Add support for #include and #includedir from Natale Vinto.

plugins/sudoers/sudoers2ldif

@@ -38,39 +38,38 @@ my %UA;
 my %HA;
 my %CA;
 my $base=$ENV{SUDOERS_BASE} or die "$0: Container SUDOERS_BASE undefined\n";
-my @options=();
+my @options = ();
 my $notBefore;
 my $notAfter;
 
-my $did_defaults=0;
+my $did_defaults = 0;
 my $order = 0;
 my %seen_users;
+my @sudoersdirs;
 
-# parse sudoers one line at a time
-while (<>){
+# Parsing is now through callbacks reading @ARGV or STDIN
+sub parse_sudoers_line {
+    my $line = shift;
 
     # remove comment
-  s/#.*//;
-
-  # line continuation
-  $_.=<> while s/\\\s*$//s;
+    $line =~ s/#.*//;
 
     # cleanup newline
-  chomp;
+    chomp $line;
 
     # ignore blank lines
-  next if /^\s*$/;
+    return if $line =~ /^\s*$/;
 
-  if (s/^Defaults\s+//) {
-    s/\s+$//; # remove trailing whitespace
+    if ($line =~ s/^Defaults\s+//) {
+	$line =~ s/\s+$//; # remove trailing whitespace
 	# remove spaces between '!', '=', '+=' and '-='
-    s/^(\S+)\s*([\+-]?=)\s*(\S.*)$/$1$2$3/ unless s/^!\s*(\S.*)$/!$1/;
-    push @options, $_;
-  } elsif (/^(\S+)\s+([^=]+)=\s*(.*)/) {
+	$line =~ s/^(\S+)\s*([\+-]?=)\s*(\S.*)$/$1$2$3/ unless $line =~ s/^!\s*(\S.*)$/!$1/;
+	push @options, $line;
+    } elsif ($line =~ /^(\S+)\s+([^=]+)=\s*(.*)/) {
 	# Aliases or Definitions
-    my ($p1,$p2,$p3)=($1,$2,$3);
-    $p2=~s/\s+$//; # remove trailing whitespace
-    $p3=~s/\s+$//; # remove trailing whitespace
+	my ($p1, $p2, $p3) = ($1, $2, $3);
+	$p2 =~ s/\s+$//; # remove trailing whitespace
+	$p3 =~ s/\s+$//; # remove trailing whitespace
 
 	if ($p1 eq "User_Alias") {
 	    $UA{$p2}=$p3;
@@ -93,7 +92,7 @@ while (<>){
 		print "\n";
 	    }
 	    # Definition
-      my @users=split /\s*,\s*/,$p1;
+	    my @users = split(/\s*,\s*/, $p1);
 	    my $username = $users[0];
 	    if ($seen_users{$username}) {
 		$seen_users{$username} += 1;
@@ -101,8 +100,8 @@ while (<>){
 	    } else {
 		$seen_users{$username} = 1;
 	    }
-      my @hosts=split /\s*,\s*/,$p2;
-      my @cmds= split /\s*,\s*/,$p3;
+	    my @hosts = split(/\s*,\s*/, $p2);
+	    my @cmds = split(/\s*,\s*/, $p3);
 	    @options=();
 	    undef $notBefore;
 	    undef $notAfter;
@@ -132,18 +131,17 @@ while (<>){
 	    print "\n";
 	}
     } else {
-    print "parse error: $_\n";
+	warn "parse error: $line\n";
     }
 }
 
-#
-# recursively expand hash elements
-sub expand{
+# Recursively expand hash elements
+sub expand {
     my $ref=shift;
     my @a=();
 
     # preen the line a little
-  foreach (@_){
+    foreach (@_) {
 	# Convert upper case command options
 	s/TIMEOUT=(\S+)\s*// && push @options,"timeout=$1";
 	s/ROLE=(\S+)\s*// && push @options,"role=$1";
@@ -172,3 +170,80 @@ sub expand{
     push @a,$ref->{$_} ? expand($ref,split /\s*,\s*/,$ref->{$_}):$_ foreach @_;
     @a;
 }
+
+# Parse sudoers, expanding #include and #includedir directives
+sub scan_sudoers_fh {
+    my ($filehandle, $callback) = @_;
+
+    while (<$filehandle>) {
+        if (/^#include\s+(.+?)\s*$/){
+            scan_sudoers_filename($1, 0, $callback);
+        } elsif (/^#includedir\s+(.+?)\s*$/){
+            scan_sudoers_dirname($1, $callback);
+        } else {
+            $callback->($_);
+        }
+    }
+}
+
+# Read from #include file
+sub scan_sudoers_filename {
+    my ($filename, $quiet, $callback) = @_;
+
+    # Keep track of the parent dir of sudoers for relative includes
+    if ($filename =~ m:^(/.*/):) {
+	push(@sudoersdirs, $1);
+    } elsif ($#sudoersdirs != -1) {
+	$filename = $sudoersdirs[$#sudoersdirs] . "/$filename";
+	push(@sudoersdirs, $sudoersdirs[$#sudoersdirs]);
+    }
+    if (open(my $fh, '<', $filename)) {
+	scan_sudoers_fh($fh, $callback);
+    } else {
+	warn "unable to open $filename: $!\n" unless $quiet;
+    }
+    pop(@sudoersdirs) unless $#sudoersdirs == -1;
+}
+
+# Read from #includedir directory
+sub scan_sudoers_dirname {
+    my ($dirname, $callback) = @_;
+
+    # Ignore a missing include dir
+    if (opendir(my $dh, $dirname)) {
+	while (readdir $dh) {
+	    # Ignore files that end in '~' or have a '.' in them
+	    next if /\./ || /~$/;
+	    scan_sudoers_filename("$dirname/$_", 1, $callback);
+	}
+	closedir($dh);
+    }
+}
+
+# Returns a sub that reads lines until continuations,
+# then it invokes the callback to do the parsing
+sub make_continuation_handler {
+    my ($callback) = @_;
+
+    my $buffer = '';
+    return sub {
+        my ($line) = @_;
+
+        if ($line =~ s/\\\s*$//) {
+            # line continuation
+            $buffer .= $line;
+        } else {
+            # parse buffer
+            $callback->($buffer . $line);
+            # empty buffer
+            $buffer='';
+        }
+    };
+}
+
+my $parser_cb = make_continuation_handler(\&parse_sudoers_line);
+if (@ARGV) {
+    scan_sudoers_filename($_, 0, $parser_cb) for @ARGV;
+} else {
+    scan_sudoers_fh(\*STDIN, $parser_cb);
+}