mirror of
https://github.com/brl/mutter.git
synced 2024-09-20 14:35:48 -04:00
51a6467968
Code: All references in the code not related to themes, keybindings, or GConf were changed from 'metacity' to 'mutter'. This includes, among other things, strings, comments, the atoms used in the message protocol, and the envvars used for debugging. The GConf schema file was reduced to the 3 settings new to mutter. The overall version was brought up to 2.27 to match current gnome. Structure: All files named '*metacity*' were renamed '*mutter*' with appropriate changes in the automake system. Files removed are doc/creating_themes, src/themes, doc/metacity-theme.dtd, metacity.doap. These files will eventually end up in an external gnome-wm-data module. Installation location: On the filesystem the mutter-plugindir was change from $(libdir)/metacity/plugins/clutter to just $(libdir)/mutter/plugins. The mutter-plugins.pc.in reflects these changes. Note: mutter.desktop.in and mutter-wm.desktop both continue to have X-GNOME-WMSettingsModule=metacity set. This allows gnome-control-center to continue using libmetacity.so for configuration. This is fine since most the general keybindings and wm settings are being read from /apps/metacity/* in gconf.
634 lines
19 KiB
Plaintext
634 lines
19 KiB
Plaintext
AC_PREREQ(2.50)
|
|
|
|
m4_define([mutter_major_version], [2])
|
|
m4_define([mutter_minor_version], [27])
|
|
# Fibonacci sequence for micro version numbering:
|
|
# 0, 1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144, 233, 377, 610, 987
|
|
m4_define([mutter_micro_version], [0])
|
|
|
|
m4_define([mutter_version],
|
|
[mutter_major_version.mutter_minor_version.mutter_micro_version])
|
|
|
|
m4_define([mutter_plugin_api_version], [2])
|
|
|
|
AC_INIT([mutter], [mutter_version],
|
|
[http://bugzilla.gnome.org/enter_bug.cgi?product=mutter])
|
|
|
|
AC_CONFIG_SRCDIR(src/core/display.c)
|
|
AC_CONFIG_HEADERS(config.h)
|
|
|
|
AM_INIT_AUTOMAKE
|
|
AM_MAINTAINER_MODE
|
|
|
|
MUTTER_MAJOR_VERSION=mutter_major_version
|
|
MUTTER_MINOR_VERSION=mutter_minor_version
|
|
MUTTER_MICRO_VERSION=mutter_micro_version
|
|
MUTTER_PLUGIN_API_VERSION=mutter_plugin_api_version
|
|
AC_SUBST(MUTTER_MAJOR_VERSION)
|
|
AC_SUBST(MUTTER_MINOR_VERSION)
|
|
AC_SUBST(MUTTER_MICRO_VERSION)
|
|
AC_SUBST(MUTTER_PLUGIN_API_VERSION)
|
|
|
|
MUTTER_PLUGIN_DIR="$libdir/$PACKAGE/plugins"
|
|
AC_SUBST(MUTTER_PLUGIN_DIR)
|
|
|
|
# Honor aclocal flags
|
|
AC_SUBST(ACLOCAL_AMFLAGS, "\${ACLOCAL_FLAGS}")
|
|
|
|
GETTEXT_PACKAGE=mutter
|
|
AC_SUBST(GETTEXT_PACKAGE)
|
|
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Name of default gettext domain])
|
|
|
|
IT_PROG_INTLTOOL([0.34.90])
|
|
AC_PROG_CC
|
|
AC_ISC_POSIX
|
|
AC_HEADER_STDC
|
|
AC_LIBTOOL_WIN32_DLL
|
|
AM_PROG_LIBTOOL
|
|
|
|
#### Integer sizes
|
|
|
|
AC_CHECK_SIZEOF(char)
|
|
AC_CHECK_SIZEOF(short)
|
|
AC_CHECK_SIZEOF(long)
|
|
AC_CHECK_SIZEOF(int)
|
|
AC_CHECK_SIZEOF(void *)
|
|
AC_CHECK_SIZEOF(long long)
|
|
AC_CHECK_SIZEOF(__int64)
|
|
|
|
## byte order
|
|
AC_C_BIGENDIAN
|
|
|
|
#### Warnings
|
|
|
|
changequote(,)dnl
|
|
if test "x$GCC" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wall[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wall" ;;
|
|
esac
|
|
|
|
# case " $CFLAGS " in
|
|
# *[\ \ ]-Wshadow[\ \ ]*) ;;
|
|
# *) CFLAGS="$CFLAGS -Wshadow" ;;
|
|
# esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wchar-subscripts[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wmissing-declarations[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wmissing-prototypes[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wnested-externs[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wnested-externs" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wpointer-arith[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wpointer-arith" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wcast-align[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wcast-align" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-Wsign-compare[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -Wsign-compare" ;;
|
|
esac
|
|
|
|
if test "x$enable_ansi" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-ansi[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -ansi" ;;
|
|
esac
|
|
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-pedantic[\ \ ]*) ;;
|
|
*) CFLAGS="$CFLAGS -pedantic" ;;
|
|
esac
|
|
fi
|
|
fi
|
|
changequote([,])dnl
|
|
|
|
MUTTER_PC_MODULES='gtk+-2.0 >= 2.10.0 pango >= 1.2.0'
|
|
|
|
AC_ARG_ENABLE(gconf,
|
|
AC_HELP_STRING([--disable-gconf],
|
|
[disable gconf usage, for embedded/size-sensitive non-GNOME builds]),,
|
|
enable_gconf=yes)
|
|
|
|
if test x$enable_gconf = xyes; then
|
|
AC_DEFINE(HAVE_GCONF,1,[Build with gconf support])
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES gconf-2.0 >= 1.2.0"
|
|
fi
|
|
|
|
AC_ARG_ENABLE(verbose-mode,
|
|
AC_HELP_STRING([--disable-verbose-mode],
|
|
[disable mutter's ability to do verbose logging, for embedded/size-sensitive custom builds]),,
|
|
enable_verbose_mode=yes)
|
|
|
|
if test x$enable_verbose_mode = xyes; then
|
|
AC_DEFINE(WITH_VERBOSE_MODE,1,[Build with verbose mode support])
|
|
fi
|
|
|
|
AC_ARG_ENABLE(sm,
|
|
AC_HELP_STRING([--disable-sm],
|
|
[disable mutter's session management support, for embedded/size-sensitive custom non-GNOME builds]),,
|
|
enable_sm=auto)
|
|
|
|
AC_ARG_ENABLE(startup-notification,
|
|
AC_HELP_STRING([--disable-startup-notification],
|
|
[disable mutter's startup notification support, for embedded/size-sensitive custom non-GNOME builds]),,
|
|
enable_startup_notification=auto)
|
|
|
|
AC_ARG_ENABLE(compositor,
|
|
AC_HELP_STRING([--disable-compositor],
|
|
[disable mutter's compositing manager]),,
|
|
enable_compositor=auto)
|
|
|
|
AC_ARG_ENABLE(clutter,
|
|
AC_HELP_STRING([--without-clutter],
|
|
[disable the use of clutter for compositing]),,
|
|
with_clutter=auto)
|
|
|
|
AC_ARG_ENABLE(introspection,
|
|
AC_HELP_STRING([--without-introspection],
|
|
[disable the use of GObject introspection]),,
|
|
with_introspection=auto)
|
|
|
|
AC_ARG_ENABLE(xsync,
|
|
AC_HELP_STRING([--disable-xsync],
|
|
[disable mutter's use of the XSync extension]),,
|
|
enable_xsync=auto)
|
|
|
|
AC_ARG_ENABLE(render,
|
|
AC_HELP_STRING([--disable-render],
|
|
[disable mutter's use of the RENDER extension]),,
|
|
enable_render=auto)
|
|
|
|
AC_ARG_ENABLE(shape,
|
|
AC_HELP_STRING([--disable-shape],
|
|
[disable mutter's use of the shaped window extension]),,
|
|
enable_shape=auto)
|
|
|
|
## try definining HAVE_BACKTRACE
|
|
AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
|
|
|
|
AM_GLIB_GNU_GETTEXT
|
|
|
|
## here we get the flags we'll actually use
|
|
# GOptionEntry requires glib-2.6.0
|
|
PKG_CHECK_MODULES(ALL, glib-2.0 >= 2.6.0)
|
|
# gtk_window_set_icon_name requires gtk2+-2.60
|
|
PKG_CHECK_MODULES(MUTTER_MESSAGE, gtk+-2.0 >= 2.6.0)
|
|
PKG_CHECK_MODULES(MUTTER_WINDOW_DEMO, gtk+-2.0 >= 2.6.0)
|
|
|
|
if $PKG_CONFIG --atleast-version 1.2.0 pangoxft; then
|
|
echo "pangoxft found"
|
|
else
|
|
AC_MSG_ERROR("Pango 1.2.0 or greater based on Xft2 is required")
|
|
fi
|
|
|
|
# Unconditionally use this dir to avoid a circular dep with gnomecc
|
|
GNOME_KEYBINDINGS_KEYSDIR="${datadir}/gnome-control-center/keybindings"
|
|
AC_SUBST(GNOME_KEYBINDINGS_KEYSDIR)
|
|
|
|
STARTUP_NOTIFICATION_VERSION=0.7
|
|
AC_MSG_CHECKING([Startup notification library >= $STARTUP_NOTIFICATION_VERSION])
|
|
if $PKG_CONFIG --atleast-version $STARTUP_NOTIFICATION_VERSION libstartup-notification-1.0; then
|
|
have_startup_notification=yes
|
|
else
|
|
have_startup_notification=no
|
|
fi
|
|
AC_MSG_RESULT($have_startup_notification)
|
|
|
|
if test x$enable_startup_notification = xyes; then
|
|
have_startup_notification=yes
|
|
echo "startup-notification support forced on"
|
|
elif test x$enable_startup_notification = xauto; then
|
|
true
|
|
else
|
|
have_startup_notification=no
|
|
fi
|
|
|
|
if test x$have_startup_notification = xyes; then
|
|
echo "Building with libstartup-notification"
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES libstartup-notification-1.0 >= $STARTUP_NOTIFICATION_VERSION"
|
|
AC_DEFINE(HAVE_STARTUP_NOTIFICATION, , [Building with startup notification support])
|
|
else
|
|
echo "Building without libstartup-notification"
|
|
fi
|
|
|
|
## init this, it gets set either in the compositor check below
|
|
## or the render-specific check later
|
|
have_xrender=no
|
|
|
|
XCOMPOSITE_VERSION=0.2
|
|
if test x$enable_compositor = xyes; then
|
|
have_xcomposite=yes
|
|
elif test x$enable_compositor = xauto; then
|
|
echo "Building compositing manager by default now."
|
|
have_xcomposite=yes
|
|
else
|
|
have_xcomposite=no
|
|
fi
|
|
|
|
if test x$with_clutter = xyes; then
|
|
have_xcomposite=yes
|
|
have_clutter=yes
|
|
elif test x$with_clutter = xauto; then
|
|
echo "Building clutter compositing manager by default now."
|
|
have_xcomposite=yes
|
|
have_clutter=yes
|
|
else
|
|
have_clutter=no
|
|
fi
|
|
|
|
AM_CONDITIONAL(WITH_CLUTTER, test "$have_clutter" = "yes")
|
|
|
|
if test x$have_xcomposite = xyes; then
|
|
AC_MSG_CHECKING([Xcomposite >= $XCOMPOSITE_VERSION])
|
|
if $PKG_CONFIG --atleast-version $XCOMPOSITE_VERSION xcomposite; then
|
|
AC_MSG_RESULT([yes])
|
|
else
|
|
AC_MSG_ERROR([no. Use --disable-compositor to disable.])
|
|
fi
|
|
fi
|
|
|
|
if test x$have_xcomposite = xyes; then
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES xcomposite >= $XCOMPOSITE_VERSION xfixes xrender xdamage"
|
|
AC_DEFINE(HAVE_COMPOSITE_EXTENSIONS, 1, [Building with compositing manager support])
|
|
echo "Building with compositing manager"
|
|
|
|
## force on render also
|
|
have_xrender=yes
|
|
else
|
|
echo "Building without compositing manager"
|
|
fi
|
|
|
|
## if no compositor, still possibly enable render
|
|
if test x$have_xcomposite = xno; then
|
|
XRENDER_VERSION=0.0
|
|
AC_MSG_CHECKING([xrender >= $XRENDER_VERSION])
|
|
if $PKG_CONFIG --atleast-version $XRENDER_VERSION xrender; then
|
|
have_xrender=yes
|
|
else
|
|
have_xrender=no
|
|
fi
|
|
AC_MSG_RESULT($have_xrender)
|
|
|
|
if test x$enable_render = xyes; then
|
|
have_xrender=yes
|
|
echo "Render support forced on"
|
|
elif test x$enable_render = xauto; then
|
|
true
|
|
else
|
|
have_xrender=no
|
|
fi
|
|
|
|
if test x$have_xrender = xyes; then
|
|
echo "Building with Render"
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES xrender >= $XRENDER_VERSION"
|
|
fi
|
|
fi ## have_composite
|
|
|
|
if test x$have_xrender = xyes; then
|
|
AC_DEFINE(HAVE_RENDER, , [Building with Render extension support])
|
|
fi
|
|
|
|
CLUTTER_PACKAGE=clutter-0.9
|
|
AC_SUBST(CLUTTER_PACKAGE)
|
|
if test x$have_clutter = xyes; then
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES $CLUTTER_PACKAGE "
|
|
PKG_CHECK_MODULES(CLUTTER, $CLUTTER_PACKAGE)
|
|
AC_DEFINE(WITH_CLUTTER, , [Building with Clutter compositor])
|
|
|
|
dnl Check for the clutter-glx-texture-pixmap header
|
|
mutter_save_cppflags="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $CLUTTER_CFLAGS"
|
|
AC_CHECK_HEADER([clutter/glx/clutter-glx-texture-pixmap.h],
|
|
[have_glx_texture_pixmap=yes],
|
|
[have_glx_texture_pixmap=no])
|
|
CPPFLAGS="$mutter_save_cppflags"
|
|
|
|
if test x$have_glx_texture_pixmap = xyes; then
|
|
AC_DEFINE(HAVE_GLX_TEXTURE_PIXMAP, ,
|
|
[Is ClutterGLXTexturePixmap available?])
|
|
fi
|
|
fi
|
|
|
|
if test x$with_introspection != xno; then
|
|
PKG_CHECK_MODULES(INTROSPECTION, gobject-introspection-1.0, have_introspection=yes, have_introspection=no)
|
|
if test x$have_introspection=xyes; then
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES gobject-introspection-1.0"
|
|
AC_DEFINE(HAVE_INTROSPECTION, 1, [Define if GObject introspection is available])
|
|
G_IR_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0`
|
|
AC_SUBST(G_IR_SCANNER)
|
|
G_IR_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0`
|
|
AC_SUBST(G_IR_COMPILER)
|
|
G_IR_GENERATE=`$PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0`
|
|
AC_SUBST(G_IR_GENERATE)
|
|
GIRDIR=`$PKG_CONFIG --variable=girdir gobject-introspection-1.0`
|
|
AC_SUBST(GIRDIR)
|
|
TYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
|
|
AC_SUBST(TYPELIBDIR)
|
|
fi
|
|
fi
|
|
AM_CONDITIONAL(WITH_INTROSPECTION, test "$have_introspection" = "yes")
|
|
|
|
AC_MSG_CHECKING([Xcursor])
|
|
if $PKG_CONFIG xcursor; then
|
|
have_xcursor=yes
|
|
else
|
|
have_xcursor=no
|
|
fi
|
|
AC_MSG_RESULT($have_xcursor)
|
|
|
|
if test x$have_xcursor = xyes; then
|
|
echo "Building with Xcursor"
|
|
MUTTER_PC_MODULES="$MUTTER_PC_MODULES xcursor"
|
|
AC_DEFINE(HAVE_XCURSOR, , [Building with Xcursor support])
|
|
fi
|
|
|
|
PKG_CHECK_MODULES(MUTTER, $MUTTER_PC_MODULES)
|
|
|
|
AC_PATH_XTRA
|
|
|
|
ALL_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
|
|
|
|
# Check for Xinerama extension (Solaris impl or Xfree impl)
|
|
mutter_save_cppflags="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
|
|
|
|
AC_ARG_ENABLE(xinerama,
|
|
AC_HELP_STRING([--disable-xinerama],
|
|
[disable mutter's use of the Xinerama extension]),
|
|
try_xinerama=$enable_xinerama,try_xinerama=yes)
|
|
|
|
use_solaris_xinerama=no
|
|
use_xfree_xinerama=no
|
|
if test "${try_xinerama}" != no; then
|
|
case "$host" in
|
|
*-*-solaris*)
|
|
# Check for solaris
|
|
use_solaris_xinerama=yes
|
|
AC_CHECK_LIB(Xext, XineramaGetInfo,
|
|
use_solaris_xinerama=yes, use_solaris_xinerama=no,
|
|
$ALL_X_LIBS)
|
|
if test "x$use_solaris_xinerama" = "xyes"; then
|
|
AC_CHECK_HEADER(X11/extensions/xinerama.h,
|
|
if test -z "`echo $ALL_X_LIBS | grep "\-lXext" 2> /dev/null`"; then
|
|
X_EXTRA_LIBS="-lXext $X_EXTRA_LIBS"
|
|
fi
|
|
AC_DEFINE(HAVE_SOLARIS_XINERAMA, , [Have Solaris-style Xinerama])
|
|
AC_DEFINE(HAVE_XINERAMA, , [Have some version of Xinerama]),
|
|
use_solaris_xinerama=no,
|
|
[#include <X11/Xlib.h>])
|
|
fi
|
|
AC_MSG_CHECKING(for Xinerama support on Solaris)
|
|
AC_MSG_RESULT($use_solaris_xinerama);
|
|
;;
|
|
*)
|
|
# Check for XFree
|
|
use_xfree_xinerama=yes
|
|
AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
|
|
[AC_CHECK_HEADER(X11/extensions/Xinerama.h,
|
|
X_EXTRA_LIBS="-lXinerama $X_EXTRA_LIBS"
|
|
if test -z "`echo $ALL_X_LIBS | grep "\-lXext" 2> /dev/null`"; then
|
|
X_EXTRA_LIBS="-lXext $X_EXTRA_LIBS"
|
|
fi
|
|
AC_DEFINE(HAVE_XFREE_XINERAMA, , [Have XFree86-style Xinerama])
|
|
AC_DEFINE(HAVE_XINERAMA,, [Have some version of Xinerama]),
|
|
use_xfree_xinerama=no,
|
|
[#include <X11/Xlib.h>])],
|
|
use_xfree_xinerama=no, -lXext $ALL_X_LIBS)
|
|
AC_MSG_CHECKING(for Xinerama support on XFree86)
|
|
AC_MSG_RESULT($use_xfree_xinerama);
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
CPPFLAGS="$mutter_save_cppflags"
|
|
|
|
SHAPE_LIBS=
|
|
found_shape=no
|
|
AC_CHECK_LIB(Xext, XShapeQueryExtension,
|
|
[AC_CHECK_HEADER(X11/extensions/shape.h,
|
|
SHAPE_LIBS=-lXext found_shape=yes)],
|
|
, $ALL_X_LIBS)
|
|
|
|
if test x$enable_shape = xno; then
|
|
found_shape=no
|
|
fi
|
|
|
|
if test x$enable_shape = xyes; then
|
|
if test "$found_shape" = "no"; then
|
|
AC_MSG_ERROR([--enable-shape forced and Shape not found])
|
|
exit 1
|
|
fi
|
|
fi
|
|
|
|
if test "x$found_shape" = "xyes"; then
|
|
AC_DEFINE(HAVE_SHAPE, , [Have the shape extension library])
|
|
fi
|
|
|
|
found_xkb=no
|
|
AC_CHECK_LIB(X11, XkbQueryExtension,
|
|
[AC_CHECK_HEADER(X11/XKBlib.h,
|
|
found_xkb=yes)],
|
|
, $ALL_X_LIBS)
|
|
|
|
if test "x$found_xkb" = "xyes"; then
|
|
AC_DEFINE(HAVE_XKB, , [Have keyboard extension library])
|
|
fi
|
|
|
|
|
|
RANDR_LIBS=
|
|
found_randr=no
|
|
AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
|
|
[AC_CHECK_HEADER(X11/extensions/Xrandr.h,
|
|
RANDR_LIBS=-lXrandr found_randr=yes,,
|
|
[#include <X11/Xlib.h>])],
|
|
, -lXrender -lXext $ALL_X_LIBS)
|
|
|
|
if test "x$found_randr" = "xyes"; then
|
|
AC_DEFINE(HAVE_RANDR, , [Have the Xrandr extension library])
|
|
fi
|
|
|
|
XSYNC_LIBS=
|
|
found_xsync=no
|
|
AC_CHECK_LIB(Xext, XSyncQueryExtension,
|
|
[AC_CHECK_HEADER(X11/extensions/sync.h,
|
|
found_xsync=yes,,
|
|
[#include <X11/Xlib.h>])],
|
|
, $ALL_X_LIBS)
|
|
|
|
if test x$enable_xsync = xno; then
|
|
found_xsync=no
|
|
fi
|
|
|
|
if test x$enable_xsync = xyes; then
|
|
if test "$found_xsync" = "no"; then
|
|
AC_MSG_ERROR([--enable-xsync forced and XSync not found])
|
|
exit 1
|
|
fi
|
|
fi
|
|
|
|
if test "x$found_xsync" = "xyes"; then
|
|
XSYNC_LIBS=-lXext
|
|
AC_DEFINE(HAVE_XSYNC, , [Have the Xsync extension library])
|
|
fi
|
|
|
|
MUTTER_LIBS="$MUTTER_LIBS $XSYNC_LIBS $RANDR_LIBS $SHAPE_LIBS $X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS -lm"
|
|
MUTTER_MESSAGE_LIBS="$MUTTER_MESSAGE_LIBS $X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
|
|
MUTTER_WINDOW_DEMO_LIBS="$MUTTER_WINDOW_DEMO_LIBS $X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
|
|
MUTTER_PROPS_LIBS="$MUTTER_PROPS_LIBS $X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
|
|
|
|
found_sm=no
|
|
case "$MUTTER_LIBS" in
|
|
*-lSM*)
|
|
found_sm=yes
|
|
;;
|
|
*)
|
|
AC_CHECK_LIB(SM, SmcSaveYourselfDone,
|
|
[AC_CHECK_HEADERS(X11/SM/SMlib.h,
|
|
MUTTER_LIBS="-lSM -lICE $MUTTER_LIBS" found_sm=yes)],
|
|
, $MUTTER_LIBS)
|
|
;;
|
|
esac
|
|
|
|
if test x$enable_sm = xno; then
|
|
found_sm=no
|
|
fi
|
|
|
|
if test x$enable_sm = xyes; then
|
|
if test "$found_sm" = "no"; then
|
|
AC_MSG_ERROR([--enable-sm forced and -lSM not found])
|
|
exit 1
|
|
fi
|
|
fi
|
|
|
|
if test "$found_sm" = "yes"; then
|
|
AC_DEFINE(HAVE_SM, , [Building with SM support])
|
|
fi
|
|
|
|
AM_CONDITIONAL(HAVE_SM, test "$found_sm" = "yes")
|
|
|
|
HOST_ALIAS=$host_alias
|
|
AC_SUBST(HOST_ALIAS)
|
|
|
|
AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
|
|
|
|
if test x"$GDK_PIXBUF_CSOURCE" = xno; then
|
|
AC_MSG_ERROR([gdk-pixbuf-csource executable not found in your path - should be installed with GTK])
|
|
fi
|
|
|
|
AC_SUBST(GDK_PIXBUF_CSOURCE)
|
|
|
|
if test x$enable_gconf = xyes; then
|
|
AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
|
|
if test x"$GCONFTOOL" = xno; then
|
|
AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
|
|
fi
|
|
|
|
AM_GCONF_SOURCE_2
|
|
else
|
|
GCONF_SCHEMAS_INSTALL_TRUE='#'
|
|
GCONF_SCHEMAS_INSTALL_FALSE=
|
|
fi
|
|
|
|
AC_PATH_PROG(ZENITY, zenity, no)
|
|
if test x"$ZENITY" = xno; then
|
|
AC_MSG_ERROR([zenity not found in your path - needed for dialogs])
|
|
fi
|
|
|
|
AC_ARG_ENABLE(debug,
|
|
[ --enable-debug enable debugging],,
|
|
enable_debug=no)
|
|
if test "x$enable_debug" = "xyes"; then
|
|
CFLAGS="$CFLAGS -g -O"
|
|
fi
|
|
|
|
# Warnings are there for a reason
|
|
if test "x$GCC" = "xyes"; then
|
|
CFLAGS="$CFLAGS -Wall -Werror -ansi"
|
|
fi
|
|
|
|
# Use gnome-doc-utils:
|
|
GNOME_DOC_INIT([0.8.0])
|
|
|
|
AC_CONFIG_FILES([
|
|
Makefile
|
|
doc/Makefile
|
|
doc/man/Makefile
|
|
src/Makefile
|
|
src/wm-tester/Makefile
|
|
src/libmutter-private.pc
|
|
src/mutter-plugins.pc
|
|
src/tools/Makefile
|
|
src/compositor/mutter/plugins/Makefile
|
|
po/Makefile.in
|
|
])
|
|
|
|
AC_OUTPUT
|
|
|
|
if test x$enable_gconf = xno; then
|
|
echo "*** WARNING WARNING WARNING WARNING WARNING"
|
|
echo "*** Building without GConf. This means there's no"
|
|
echo "*** way to change prefs except hacking source code."
|
|
echo "*** This is intended for embedded systems etc., not for normal use."
|
|
fi
|
|
|
|
if test x$enable_verbose_mode = xno; then
|
|
echo "*** WARNING WARNING WARNING WARNING WARNING"
|
|
echo "*** Building without verbose mode"
|
|
echo "*** This means there's no way to debug mutter problems."
|
|
echo "*** Please build normal desktop versions of mutter"
|
|
echo "*** with verbose mode enabled so users can use it when they report bugs."
|
|
fi
|
|
|
|
dnl ==========================================================================
|
|
echo "
|
|
mutter-$VERSION:
|
|
|
|
prefix: ${prefix}
|
|
source code location: ${srcdir}
|
|
compiler: ${CC}
|
|
|
|
GConf: ${enable_gconf}
|
|
XFree86 Xinerama: ${use_xfree_xinerama}
|
|
Solaris Xinerama: ${use_solaris_xinerama}
|
|
Startup notification: ${have_startup_notification}
|
|
Compositing manager: ${have_xcomposite}
|
|
Introspection: ${have_introspection}
|
|
Session management: ${found_sm}
|
|
Shape extension: ${found_shape}
|
|
Resize-and-rotate: ${found_randr}
|
|
Xsync: ${found_xsync}
|
|
Render: ${have_xrender}
|
|
Xcursor: ${have_xcursor}
|
|
Clutter: ${have_clutter}
|
|
"
|
|
|
|
MUTTER_MINOR_VERSION=mutter_minor_version
|
|
if test $(( $(echo $MUTTER_MINOR_VERSION) %2)) == "1"; then
|
|
stable_version=$(( ($MUTTER_MINOR_VERSION / 2) * 2))
|
|
echo "This is the UNSTABLE branch of mutter"
|
|
echo -n "Use 2.$stable_version.x for stable "
|
|
echo "(gnome-2-$stable_version branch in Subversion)"
|
|
else
|
|
echo "This is the stable branch of mutter"
|
|
fi
|