mirror of
https://github.com/brl/mutter.git
synced 2024-11-25 09:30:45 -05:00
d360b25b81
If a library is provided in the positional arguments, then meson defaults to installing the .pc file in a 'pkgconfig' subdirectory in the library's install location. We want the files in the regular $libdir/pkgconfig rather than $libdir/mutter-$api/pkgconfig, so specify the location explicitly in the parameters. https://gitlab.gnome.org/GNOME/mutter/merge_requests/382
82 lines
2.1 KiB
Meson
82 lines
2.1 KiB
Meson
cogl_pango_sources = [
|
|
'cogl-pango-display-list.c',
|
|
'cogl-pango-display-list.h',
|
|
'cogl-pango-fontmap.c',
|
|
'cogl-pango-glyph-cache.c',
|
|
'cogl-pango-glyph-cache.h',
|
|
'cogl-pango-pipeline-cache.c',
|
|
'cogl-pango-pipeline-cache.h',
|
|
'cogl-pango-private.h',
|
|
'cogl-pango-render.c',
|
|
]
|
|
|
|
cogl_pango_public_headers = [
|
|
'cogl-pango.h',
|
|
]
|
|
|
|
cogl_pango_deps = [
|
|
cogl_deps,
|
|
pango_dep,
|
|
pangocairo_dep,
|
|
libmutter_cogl_dep,
|
|
]
|
|
|
|
libmutter_cogl_pango = shared_library('mutter-cogl-pango-' + libmutter_api_version,
|
|
sources: [cogl_pango_sources, cogl_pango_public_headers],
|
|
soversion: '0.0.0',
|
|
c_args: cogl_c_args,
|
|
include_directories: [cogl_includepath, cogl_path_includepath],
|
|
link_depends: 'libmutter-cogl-pango.map',
|
|
dependencies: [cogl_pango_deps],
|
|
install_rpath: pkglibdir,
|
|
install_dir: pkglibdir,
|
|
install: true,
|
|
)
|
|
|
|
libmutter_cogl_pango_dep = declare_dependency(
|
|
link_with: libmutter_cogl_pango,
|
|
)
|
|
|
|
if have_introspection
|
|
libmutter_cogl_pango_gir = gnome.generate_gir(libmutter_cogl_pango,
|
|
sources: cogl_pango_public_headers,
|
|
nsversion: libmutter_api_version,
|
|
namespace: 'CoglPango',
|
|
symbol_prefix: 'cogl_pango',
|
|
header: 'cogl-pango.h',
|
|
includes: [
|
|
libmutter_cogl_gir[0],
|
|
'Pango-1.0',
|
|
'PangoCairo-1.0'
|
|
],
|
|
dependencies: [
|
|
cogl_deps,
|
|
pango_dep,
|
|
libmutter_cogl_pango_dep,
|
|
],
|
|
extra_args: introspection_args + [
|
|
'-UCOGL_COMPILATION',
|
|
'-DG_LOG_DOMAIN=\"CoglPango\"',
|
|
],
|
|
install_dir_gir: pkglibdir,
|
|
install_dir_typelib: pkglibdir,
|
|
install: true
|
|
)
|
|
endif
|
|
|
|
cogl_pango_includedir = join_paths(cogl_includedir, 'cogl-pango')
|
|
install_headers(cogl_pango_public_headers, subdir: cogl_pango_includedir)
|
|
|
|
pkg.generate(libmutter_cogl_pango,
|
|
name: 'CoglPango',
|
|
filebase: 'mutter-cogl-pango-' + libmutter_api_version,
|
|
description: 'A text rendering for Cogl in mutter',
|
|
subdirs: join_paths(pkgname, 'cogl'),
|
|
requires: [cogl_pkg_deps, libmutter_cogl_name],
|
|
version: meson.project_version(),
|
|
variables: [
|
|
'apiversion=' + libmutter_api_version,
|
|
],
|
|
install_dir: pcdir,
|
|
)
|