forked from brl/citadel
Bruce Leidl
f4f1f3b153
* citadel-kernel 5.15.8 -> 5.18 * adwaita-icon-theme 42.0 * ell 0.44 -> 0.50 * libnma 1.8.30 -> 1.8.38 * iwd 1.17 -> 1.27 * modemmanager 1.16.8 -> 1.18.6 * networkmanager 1.32.10 -> 1.36.2 * networkmanager-openvpn 1.8.14 -> 1.8.18 * accountsservice 0.6.55 -> 22.08.8 * colord-gtk 0.1.26 -> 0.3.0 * polkit 0.118 -> 0.119 * gexiv2 0.12.1 -> 0.14.0 * gjs 1.70.0 -> 1.72.0 * gnome-autoar 0.4.1 -> 0.4.3 * gnome-backgrounds 0.41.0 -> 0.42.0 * gnome-bluetooth 0.34.3 -> 42.0 * gnome-control-center 41.1 -> 42.1 * gnome-desktop 41.1 -> 42.1 * gnome-disk-utility 41.0 -> 42.0 * gnome-screenshot 40.0 -> 41.0 * gnome-session 40.1.1 -> 42.0 * gnome-settings-daemon 41.0 -> 42.1 * gnome-shell 41.1 -> 42.1 * gnome-system-monitor 41.0 -> 42.0 * gnome-terminal 3.42.1 -> 3.42.2 * gtk4 4.4.1 -> 4.6.4 * gvfs 1.48.1 -> 1.50.0 * libgweather 40.0 -> libgweather4 4.0.0 * mutter 41.1 -> 42.1 * network-manager-applet 1.18.0 -> 1.26.0 * yelp 3.36 -> 42.1 * yelp-xsl 3.36 -> 42.0 * yelp-tools 3.32.2 -> 42.0 * zenity 3.30.0 -> 3.42.1
90 lines
3.5 KiB
BlitzBasic
90 lines
3.5 KiB
BlitzBasic
DESCRIPTION = "gvfs is a userspace virtual filesystem"
|
|
LICENSE = "LGPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=05df38dd77c35ec8431f212410a3329e"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
inherit gnomebase gsettings bash-completion gettext upstream-version-is-even features_check useradd
|
|
|
|
DEPENDS += "libsecret glib-2.0 glib-2.0-native libgudev shadow-native \
|
|
gsettings-desktop-schemas dbus"
|
|
|
|
RDEPENDS:${PN} += "gsettings-desktop-schemas"
|
|
|
|
SRC_URI = "https://download.gnome.org/sources/${BPN}/${@gnome_verdir("${PV}")}/${BPN}-${PV}.tar.xz;name=archive"
|
|
|
|
SRC_URI[archive.sha256sum] = "cbc2f564d2e9f00c760673f42d6803bce3e081ab7ffb4456deffffba9339b4dd"
|
|
|
|
# depends on gsettings-desktop-schemas->gcr->gtk+3-> x11
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
EXTRA_OEMESON = " \
|
|
-Dbluray=false \
|
|
-Dgoa=false \
|
|
-Dgoogle=false \
|
|
-Dnfs=false \
|
|
"
|
|
|
|
PACKAGES =+ "gvfsd-ftp gvfsd-sftp gvfsd-trash"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/glib-2.0 \
|
|
${datadir}/GConf \
|
|
${datadir}/dbus-1/services \
|
|
${libdir}/gio/modules/*.so \
|
|
${libdir}/tmpfiles.d \
|
|
${systemd_user_unitdir} \
|
|
"
|
|
|
|
FILES:${PN}-dbg += "${libdir}/gio/modules/.debug/*"
|
|
FILES:${PN}-dev += "${libdir}/gio/modules/*.la"
|
|
|
|
FILES:gvfsd-ftp = "${libexecdir}/gvfsd-ftp ${datadir}/gvfs/mounts/ftp.mount"
|
|
FILES:gvfsd-sftp = "${libexecdir}/gvfsd-sftp ${datadir}/gvfs/mounts/sftp.mount"
|
|
FILES:gvfsd-trash = "${libexecdir}/gvfsd-trash ${datadir}/gvfs/mounts/trash.mount"
|
|
|
|
RRECOMMENDS:gvfsd-ftp += "openssh-sftp openssh-ssh"
|
|
|
|
PACKAGECONFIG ?= "libgphoto2 \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','polkit','udisks2','',d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','polkit','admin','',d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[udisks2] = "-Dudisks2=true, -Dudisks2=false, udisks2, udisks2"
|
|
PACKAGECONFIG[admin] = "-Dadmin=true, -Dadmin=false, libcap polkit"
|
|
PACKAGECONFIG[afc] = "-Dafc=true, -Dafc=false, libimobiledevice libplist"
|
|
PACKAGECONFIG[archive] = "-Darchive=true, -Darchive=false, libarchive"
|
|
PACKAGECONFIG[dnssd] = "-Ddnssd=true, -Ddnssd=false, avahi"
|
|
PACKAGECONFIG[gcr] = "-Dgcr=true, -Dgcr=false, gcr"
|
|
PACKAGECONFIG[http] = "-Dhttp=true, -Dhttp=false, libsoup-2.4"
|
|
PACKAGECONFIG[libmtp] = "-Dmtp=true, -Dmtp=false, libmtp"
|
|
PACKAGECONFIG[logind] = "-Dlogind=true, -Dlogind=false, systemd"
|
|
PACKAGECONFIG[libgphoto2] = "-Dgphoto2=true, -Dgphoto2=false, libgphoto2"
|
|
PACKAGECONFIG[samba] = "-Dsmb=true, -Dsmb=false, samba"
|
|
PACKAGECONFIG[systemd] = "-Dsystemduserunitdir=${systemd_user_unitdir} -Dtmpfilesdir=${libdir}/tmpfiles.d, -Dsystemduserunitdir=no -Dtmpfilesdir=no, systemd"
|
|
|
|
# needs meta-filesystems
|
|
PACKAGECONFIG[fuse] = "-Dfuse=true, -Dfuse=false, fuse3"
|
|
|
|
# libcdio-paranoia recipe doesn't exist yet
|
|
PACKAGECONFIG[cdda] = "-Dcdda=true, -Dcdda=false, libcdio-paranoia"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/${BPN}-1 polkitd"
|
|
|
|
do_install:append() {
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'polkit', 'true', 'false', d)}; then
|
|
# Fix up permissions on polkit rules.d to work with rpm4 constraints
|
|
chmod 700 ${D}/${datadir}/polkit-1/rules.d
|
|
chown polkitd:root ${D}/${datadir}/polkit-1/rules.d
|
|
fi
|
|
|
|
# After rebuilds (not from scracth) it can happen that the executables in
|
|
# libexec ar missing executable permission flag. Not sure but it came up
|
|
# during transition to meson. Looked into build files and logs but could
|
|
# not find suspicious
|
|
for exe in `find ${D}/${libexecdir}`; do
|
|
chmod +x $exe
|
|
done
|
|
}
|