forked from brl/citadel
Bruce Leidl
3db0a6b032
poky: Upgrade to Yocto 4.1 Langdale meta-citadel/recipes-kernel: citadel-kernel 5.19.9 -> 6.0.8 meta-citadel/recipes-sway: sway 1.5.1 -> 1.7 (meta-wayland) wlroots 0.12.0 -> 0.15.1 (meta-wayland) meta-gnome/recipes-connectivity: iwd 1.27 -> 1.30 (meta-oe) modemmanager 1.18.2 -> 1.18.6 (meta-oe) networkmanager 1.36.2 -> 1.40.0 (meta-oe) meta-gnome/recipes-freedesktop: libgusb 0.3.7 -> 0.3.10 (meta-oe) meta-gnome/recipes-gnome: adwaita-icon-theme 42 -> 43 (oe-core) geocode-glib 3.26.2 -> 3.26.4 (meta-oe) gjs 1.72.0 -> 1.73.2 (meta-oe) gnome-bluetooth 42.0 -> 42.4 (meta-oe) gnome-control-center 42.1 -> 43.0 gnome-desktop 42.1 -> 43.rc gnome-settings-daemon 42.1 -> 43.0 gnome-shell 42.1 -> 43.0 gsettings-desktop-schema 41.0 -> 43.0 gtk4 4.6.4 -> 4.6.7 (meta-oe) gvfs 1.50.0 -> 1.50.2 (meta-oe) libadwaita 1.1.1 -> 1.2.0 (meta-oe) libgee 0.20.4 -> 0.20.6 (meta-oe) mutter 42.1 -> 43.0 rest 0.8.1 -> 0.9.0 (meta-oe) meta-gnome/recipes-support: ell 0.50 -> 0.53 (poky) exiv2 0.26 -> 0.27.3 (meta-oe) graphene 1.10.2 -> 1.10.8 (meta-oe) gsound 1.0.2 -> 1.0.3 (meta-oe) icu_71.1 (removed from meta-gnome because this version is in poky) jansson 2.12 -> 2.14 (meta-oe) lcms 2.9 -> 2.14 (meta-oe) libdvdread 6.1.1 -> 6.1.3 (meta-oe) libndp 1.6 -> 1.8 (meta-oe) mozjs 91.8.0 -> 102.3.0 power-profiles-daemon 0.12 (new-recipe)
101 lines
2.4 KiB
BlitzBasic
101 lines
2.4 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
libsm \
|
|
virtual/libx11 \
|
|
libxi \
|
|
glib-2.0 \
|
|
libwacom \
|
|
xcomposite \
|
|
libinput \
|
|
libcanberra \
|
|
mesa \
|
|
upower \
|
|
xwayland \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
graphene \
|
|
graphene-native \
|
|
wayland-protocols \
|
|
wayland-native \
|
|
zenity \
|
|
gobject-introspection \
|
|
gobject-introspection-native \
|
|
"
|
|
|
|
RDEPENDS:${PN} += " xwayland zenity"
|
|
|
|
SRCREV = "901190c5a5edbef9c41f8101f3b9ded50ea26c9e"
|
|
|
|
EXTERNAL_TREE_VAR="CITADEL_MUTTER_PATH"
|
|
GIT_URI = "git://github.com/brl/mutter.git;branch=citadel-43.0;protocol=https"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext upstream-version-is-even features_check external-tree
|
|
|
|
# x11 is still mandatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "x11 systemd"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dremote_desktop=false \
|
|
-Dtests=false \
|
|
-Dprofiler=false \
|
|
-Dcogl_tests=false \
|
|
-Dlibwacom=true \
|
|
-Dxwayland_initfd=disabled \
|
|
-Dxwayland_path=/usr/bin/Xwayland \
|
|
-Dgles2_libname=libGLESv2.so.2 \
|
|
"
|
|
|
|
MUTTER_API_NAME = "mutter-11"
|
|
|
|
do_install:append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES:${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES:${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
|