forked from brl/citadel
Bruce Leidl
f4f1f3b153
* citadel-kernel 5.15.8 -> 5.18 * adwaita-icon-theme 42.0 * ell 0.44 -> 0.50 * libnma 1.8.30 -> 1.8.38 * iwd 1.17 -> 1.27 * modemmanager 1.16.8 -> 1.18.6 * networkmanager 1.32.10 -> 1.36.2 * networkmanager-openvpn 1.8.14 -> 1.8.18 * accountsservice 0.6.55 -> 22.08.8 * colord-gtk 0.1.26 -> 0.3.0 * polkit 0.118 -> 0.119 * gexiv2 0.12.1 -> 0.14.0 * gjs 1.70.0 -> 1.72.0 * gnome-autoar 0.4.1 -> 0.4.3 * gnome-backgrounds 0.41.0 -> 0.42.0 * gnome-bluetooth 0.34.3 -> 42.0 * gnome-control-center 41.1 -> 42.1 * gnome-desktop 41.1 -> 42.1 * gnome-disk-utility 41.0 -> 42.0 * gnome-screenshot 40.0 -> 41.0 * gnome-session 40.1.1 -> 42.0 * gnome-settings-daemon 41.0 -> 42.1 * gnome-shell 41.1 -> 42.1 * gnome-system-monitor 41.0 -> 42.0 * gnome-terminal 3.42.1 -> 3.42.2 * gtk4 4.4.1 -> 4.6.4 * gvfs 1.48.1 -> 1.50.0 * libgweather 40.0 -> libgweather4 4.0.0 * mutter 41.1 -> 42.1 * network-manager-applet 1.18.0 -> 1.26.0 * yelp 3.36 -> 42.1 * yelp-xsl 3.36 -> 42.0 * yelp-tools 3.32.2 -> 42.0 * zenity 3.30.0 -> 3.42.1
63 lines
2.3 KiB
BlitzBasic
63 lines
2.3 KiB
BlitzBasic
SUMMARY = "ModemManager is a daemon controlling broadband devices/connections"
|
|
DESCRIPTION = "ModemManager is a DBus-activated daemon which controls mobile broadband (2G/3G/4G) devices and connections"
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/ModemManager/"
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
inherit gnomebase gettext systemd gobject-introspection bash-completion
|
|
|
|
DEPENDS = "glib-2.0 libgudev libxslt-native dbus"
|
|
|
|
SRCREV ?= "a7bcf2036b34d5043dbc33fee7d98bae5859c4d3"
|
|
|
|
# Patches 0001, 0002 will be in ModemManager > 1.18.6
|
|
SRC_URI = " \
|
|
git://gitlab.freedesktop.org/mobile-broadband/ModemManager.git;protocol=https;branch=mm-1-18 \
|
|
file://0001-core-switch-bash-shell-scripts-to-use-bin-sh-for-use.patch \
|
|
file://0002-fcc-unlock-Make-scripts-POSIX-shell-compatible.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# strict, permissive
|
|
MODEMMANAGER_POLKIT_TYPE ??= "permissive"
|
|
|
|
PACKAGECONFIG ??= "vala mbim qmi \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd polkit', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[at] = "-Dat_command_via_dbus=true"
|
|
PACKAGECONFIG[systemd] = " \
|
|
-Dsystemdsystemunitdir=${systemd_unitdir}/system/, \
|
|
-Dsystemdsystemunitdir=no -Dsystemd_journal=false -Dsystemd_suspend_resume=false \
|
|
"
|
|
PACKAGECONFIG[polkit] = "-Dpolkit=${MODEMMANAGER_POLKIT_TYPE},-Dpolkit=no,polkit"
|
|
# Support WWAN modems and devices which speak the Mobile Interface Broadband Model (MBIM) protocol.
|
|
PACKAGECONFIG[mbim] = "-Dmbim=true,-Dmbim=false -Dplugin_dell=disabled -Dplugin_foxconn=disabled,libmbim"
|
|
# Support WWAN modems and devices which speak the Qualcomm MSM Interface (QMI) protocol.
|
|
PACKAGECONFIG[qmi] = "-Dqmi=true,-Dqmi=false,libqmi"
|
|
PACKAGECONFIG[qrtr] = "-Dqrtr=true,-Dqrtr=false,libqrtr-glib"
|
|
PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false"
|
|
|
|
inherit ${@bb.utils.contains('PACKAGECONFIG', 'vala', 'vala', '', d)}
|
|
|
|
EXTRA_OEMESON = " \
|
|
-Dudevdir=${nonarch_base_libdir}/udev \
|
|
-Dqrtr=false \
|
|
"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/icons \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/ModemManager \
|
|
${libdir}/ModemManager \
|
|
${systemd_unitdir}/system \
|
|
"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "ModemManager.service"
|