forked from brl/citadel
Bruce Leidl
8bb03a0582
yocto yocto-3.3 -> yocto-3.3.3 kernel 5.12.4 -> 5.14.9 cryptsetup 2.3.5 -> 2.3.6 libblockdev 2.25 -> 2.26 libbytesize 1.4 -> 2.6 nano 5.6 -> 5.8 udisks2 2.9.2 -> 2.9.3 iwd 1.13 -> 1.17 modemmanager 1.8.2 -> 1.16.8 networkmanager 1.30.2 -> 1.32.10 libgusb 0.2.11 -> 0.3.7 upower 0.99.11 -> 0.99.13 gdm 40.0 -> 41.0 gjs 1.68.0 -> 1.70.0 glib 2.68.0 -> 2.70.0 gnome-backgrounds 40.0 -> 41.0 gnome-control-center 40.0 -> 41.0 gnome-desktop 40.0 -> 41.0 gnome-disk-utility 40.1 -> 41.0 gnome-system-monitor 40.1 -> 41.0 gnome-settings-daemon 40.0.1 -> 41.0 gnome-shell 40.0 -> 41.0 mutter 40.0 -> 41.0 gsettings-desktop-schemas 40.0 -> 41.0 gtk4 4.1.12 -> 4.4.0 gvfs 1.46.1 -> 1.48.1 gnome-terminal 3.40.1 -> 3.41.1 ell 0.39 -> 0.44 mozjs 78.0.1 -> 78.11.0 vte 0.64.0 -> 0.64.2
197 lines
7.0 KiB
PHP
197 lines
7.0 KiB
PHP
SUMMARY = "A general-purpose utility library"
|
|
DESCRIPTION = "GLib is a general-purpose utility library, which provides many useful data types, macros, type conversions, string utilities, file utilities, a main loop abstraction, and so on."
|
|
HOMEPAGE = "https://developer.gnome.org/glib/"
|
|
|
|
# docs/reference/COPYING is with a 'public domain'-like license!
|
|
LICENSE = "LGPLv2.1+ & BSD & PD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
|
|
file://glib/glib.h;beginline=4;endline=17;md5=b88abb7f3ad09607e71cb9d530155906 \
|
|
file://gmodule/COPYING;md5=4fbd65380cdd255951079008b364516c \
|
|
file://gmodule/gmodule.h;beginline=4;endline=17;md5=b88abb7f3ad09607e71cb9d530155906 \
|
|
file://docs/reference/COPYING;md5=f51a5100c17af6bae00735cd791e1fcc"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
|
|
CVE_PRODUCT = "glib"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
DEPENDS = "glib-2.0-native \
|
|
virtual/libintl \
|
|
virtual/libiconv \
|
|
libffi \
|
|
libpcre \
|
|
zlib"
|
|
|
|
PACKAGES += "${PN}-codegen ${PN}-utils"
|
|
|
|
LEAD_SONAME = "libglib-2.0.*"
|
|
|
|
inherit meson gettext gtk-doc pkgconfig ptest-gnome upstream-version-is-even bash-completion gio-module-cache manpages
|
|
|
|
DEPENDS_append_class-target = "${@' gtk-doc' if d.getVar('GTKDOC_ENABLED') == 'True' else ''}"
|
|
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
|
|
S = "${WORKDIR}/glib-${PV}"
|
|
|
|
PACKAGECONFIG ??= "libmount \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
|
|
PACKAGECONFIG[libmount] = "-Dlibmount=enabled,-Dlibmount=disabled,util-linux"
|
|
PACKAGECONFIG[manpages] = "-Dman=true, -Dman=false, libxslt-native xmlto-native"
|
|
# libelf is auto-detected without a configuration option
|
|
PACKAGECONFIG[libelf] = ",,elfutils"
|
|
PACKAGECONFIG[tests] = "-Dinstalled_tests=true,-Dinstalled_tests=false,dbus"
|
|
|
|
EXTRA_OEMESON = "-Ddtrace=false -Dfam=false -Dsystemtap=false -Dselinux=disabled"
|
|
|
|
do_configure_prepend() {
|
|
sed -i -e '1s,#!.*,#!${USRBINPATH}/env python3,' ${S}/gio/gdbus-2.0/codegen/gdbus-codegen.in
|
|
}
|
|
|
|
FILES_${PN} = "${libdir}/lib*${SOLIBS} \
|
|
${libdir}/gio \
|
|
${libexecdir}/*gio-querymodules \
|
|
${datadir}/glib-2.0/schemas"
|
|
|
|
FILES_${PN}-utils += "${bindir}/glib-genmarshal \
|
|
${bindir}/glib-gettextize \
|
|
${bindir}/glib-mkenums \
|
|
${bindir}/glib-compile-resources"
|
|
|
|
FILES_${PN}-dev += "${libdir}/glib-2.0/include \
|
|
${libdir}/gio/modules/lib*${SOLIBSDEV} \
|
|
${libdir}/gio/modules/*.la \
|
|
${datadir}/glib-2.0/gettext/po/Makefile.in.in \
|
|
${datadir}/glib-2.0/schemas/gschema.dtd \
|
|
${datadir}/glib-2.0/valgrind/glib.supp \
|
|
${datadir}/gettext/its"
|
|
FILES_${PN}-dbg += "${datadir}/glib-2.0/gdb ${datadir}/gdb"
|
|
FILES_${PN}-codegen = "${datadir}/glib-2.0/codegen/*.py \
|
|
${bindir}/gdbus-codegen"
|
|
FILES_${PN}-utils = "${bindir}/*"
|
|
|
|
SHAREDMIMEDEP = "shared-mime-info"
|
|
SHAREDMIMEDEP_class-native = ""
|
|
# When cross compiling for Windows we don't want to include this
|
|
SHAREDMIMEDEP_mingw32 = ""
|
|
|
|
RRECOMMENDS_${PN} += "${SHAREDMIMEDEP}"
|
|
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
# Valgrind runtime detection works using hand-written assembly, which
|
|
# doesn't support mips16e
|
|
CPPFLAGS_append_class-target_mips16e = " -DNVALGRIND=1"
|
|
|
|
# GLib generally requires gettext to be present so for USE_NLS to yes. For
|
|
# native builds as i18n is disabled globally we have to add a gettext-native dependency.
|
|
USE_NLS_class-target = "yes"
|
|
USE_NLS_class-nativesdk = "yes"
|
|
DEPENDS_append_class-native = " gettext-native"
|
|
|
|
EXEEXT = ""
|
|
EXEEXT_mingw32 = ".exe"
|
|
|
|
do_install_append () {
|
|
if [ -f ${D}${bindir}/gtester-report ]; then
|
|
sed ${D}${bindir}/gtester-report -i -e '1s|^#!.*|#!/usr/bin/env python3|'
|
|
fi
|
|
|
|
# Remove some unpackaged files
|
|
rm -rf ${D}${datadir}/glib-2.0/codegen/__pycache__
|
|
rm -f ${D}${datadir}/glib-2.0/codegen/*.pyc
|
|
rm -f ${D}${datadir}/glib-2.0/codegen/*.pyo
|
|
|
|
if [ -e ${D}${libdir}/charset.alias ]; then
|
|
rm -f ${D}${libdir}/charset.alias
|
|
fi
|
|
|
|
# Make sure gio-querymodules is unique among multilibs
|
|
if test "x${MLPREFIX}" != "x"; then
|
|
mv ${D}${libexecdir}/gio-querymodules${EXEEXT} ${D}${libexecdir}/${MLPREFIX}gio-querymodules${EXEEXT}
|
|
fi
|
|
# Autotools does this, meson does not
|
|
mkdir -p ${D}${libdir}/gio/modules
|
|
}
|
|
|
|
do_install_append_class-target () {
|
|
# Tests are only installed on targets, not native builds. Separating this out
|
|
# keeps glib-2.0-native from depending on DISTRO_FEATURES
|
|
if [ -f ${D}${datadir}/installed-tests/glib/gdbus-serialization.test ]; then
|
|
if ${@bb.utils.contains("DISTRO_FEATURES", "x11", "false", "true", d)}; then
|
|
rm ${D}${datadir}/installed-tests/glib/gdbus-serialization.test
|
|
fi
|
|
fi
|
|
if [ -f ${D}${datadir}/installed-tests/glib/static-link.test ]; then
|
|
if test "x${MLPREFIX}" != "x"; then
|
|
mv ${D}${datadir}/installed-tests/glib/static-link.test ${D}${datadir}/installed-tests/glib/${MLPREFIX}static-link.test
|
|
fi
|
|
fi
|
|
}
|
|
|
|
# As we do not build python3 for windows, makes no sense to ship the script that's using it
|
|
do_install_append_mingw32() {
|
|
rm -f ${D}${bindir}/gtester-report
|
|
}
|
|
|
|
CODEGEN_PYTHON_RDEPENDS = "python3 python3-distutils python3-xml"
|
|
CODEGEN_PYTHON_RDEPENDS_mingw32 = ""
|
|
|
|
RDEPENDS_${PN}-codegen += "${CODEGEN_PYTHON_RDEPENDS}"
|
|
|
|
RDEPENDS_${PN}-ptest += "${PN}-utils"
|
|
|
|
RDEPENDS_${PN}-ptest += "\
|
|
coreutils \
|
|
libgcc \
|
|
dbus \
|
|
gnome-desktop-testing \
|
|
tzdata \
|
|
tzdata-americas \
|
|
tzdata-asia \
|
|
tzdata-europe \
|
|
tzdata-posix \
|
|
shared-mime-info \
|
|
${PN}-locale-ja \
|
|
${PN}-locale-fr \
|
|
${PN}-locale-el \
|
|
${PN}-locale-hr \
|
|
${PN}-locale-lt \
|
|
${PN}-locale-pl \
|
|
${PN}-locale-ru \
|
|
${PN}-locale-th \
|
|
python3-core \
|
|
python3-modules \
|
|
${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'python3-dbusmock', '', d)} \
|
|
${PN}-codegen \
|
|
"
|
|
|
|
RDEPENDS_${PN}-ptest_append_libc-glibc = "\
|
|
glibc-gconv-utf-16 \
|
|
glibc-charmap-utf-8 \
|
|
glibc-gconv-cp1255 \
|
|
glibc-charmap-cp1255 \
|
|
glibc-gconv-utf-32 \
|
|
glibc-gconv-utf-7 \
|
|
glibc-gconv-euc-jp \
|
|
glibc-gconv-iso8859-1 \
|
|
glibc-gconv-iso8859-15 \
|
|
glibc-charmap-invariant \
|
|
glibc-localedata-translit-cjk-variants \
|
|
locale-base-tr-tr \
|
|
locale-base-lt-lt \
|
|
locale-base-ja-jp.euc-jp \
|
|
locale-base-fa-ir \
|
|
locale-base-ru-ru \
|
|
locale-base-de-de \
|
|
locale-base-hr-hr \
|
|
locale-base-el-gr \
|
|
locale-base-fr-fr \
|
|
locale-base-es-es \
|
|
locale-base-en-gb \
|
|
locale-base-en-us \
|
|
locale-base-pl-pl \
|
|
locale-base-pl-pl.iso-8859-2 \
|
|
"
|