forked from brl/citadel
Bruce Leidl
3db0a6b032
poky: Upgrade to Yocto 4.1 Langdale meta-citadel/recipes-kernel: citadel-kernel 5.19.9 -> 6.0.8 meta-citadel/recipes-sway: sway 1.5.1 -> 1.7 (meta-wayland) wlroots 0.12.0 -> 0.15.1 (meta-wayland) meta-gnome/recipes-connectivity: iwd 1.27 -> 1.30 (meta-oe) modemmanager 1.18.2 -> 1.18.6 (meta-oe) networkmanager 1.36.2 -> 1.40.0 (meta-oe) meta-gnome/recipes-freedesktop: libgusb 0.3.7 -> 0.3.10 (meta-oe) meta-gnome/recipes-gnome: adwaita-icon-theme 42 -> 43 (oe-core) geocode-glib 3.26.2 -> 3.26.4 (meta-oe) gjs 1.72.0 -> 1.73.2 (meta-oe) gnome-bluetooth 42.0 -> 42.4 (meta-oe) gnome-control-center 42.1 -> 43.0 gnome-desktop 42.1 -> 43.rc gnome-settings-daemon 42.1 -> 43.0 gnome-shell 42.1 -> 43.0 gsettings-desktop-schema 41.0 -> 43.0 gtk4 4.6.4 -> 4.6.7 (meta-oe) gvfs 1.50.0 -> 1.50.2 (meta-oe) libadwaita 1.1.1 -> 1.2.0 (meta-oe) libgee 0.20.4 -> 0.20.6 (meta-oe) mutter 42.1 -> 43.0 rest 0.8.1 -> 0.9.0 (meta-oe) meta-gnome/recipes-support: ell 0.50 -> 0.53 (poky) exiv2 0.26 -> 0.27.3 (meta-oe) graphene 1.10.2 -> 1.10.8 (meta-oe) gsound 1.0.2 -> 1.0.3 (meta-oe) icu_71.1 (removed from meta-gnome because this version is in poky) jansson 2.12 -> 2.14 (meta-oe) lcms 2.9 -> 2.14 (meta-oe) libdvdread 6.1.1 -> 6.1.3 (meta-oe) libndp 1.6 -> 1.8 (meta-oe) mozjs 91.8.0 -> 102.3.0 power-profiles-daemon 0.12 (new-recipe)
98 lines
3.5 KiB
BlitzBasic
98 lines
3.5 KiB
BlitzBasic
SUMMARY = "Startup script and systemd unit file for the Weston Wayland compositor"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
SRC_URI = "file://init \
|
|
file://weston.env \
|
|
file://weston.ini \
|
|
file://weston.service \
|
|
file://weston.socket \
|
|
file://weston-autologin \
|
|
file://weston-start"
|
|
|
|
S = "${WORKDIR}"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG:append:qemuriscv64 = " use-pixman"
|
|
PACKAGECONFIG:append:qemuppc64 = " use-pixman"
|
|
|
|
PACKAGECONFIG[no-idle-timeout] = ",,"
|
|
PACKAGECONFIG[use-pixman] = ",,"
|
|
|
|
DEFAULTBACKEND ??= ""
|
|
DEFAULTBACKEND:qemuall ?= "drm"
|
|
|
|
do_install() {
|
|
if [ "${VIRTUAL-RUNTIME_init_manager}" != "systemd" ]; then
|
|
install -Dm755 ${WORKDIR}/init ${D}/${sysconfdir}/init.d/weston
|
|
sed -i 's#ROOTHOME#${ROOT_HOME}#' ${D}/${sysconfdir}/init.d/weston
|
|
fi
|
|
install -D -p -m0644 ${WORKDIR}/weston.ini ${D}${sysconfdir}/xdg/weston/weston.ini
|
|
install -Dm644 ${WORKDIR}/weston.env ${D}${sysconfdir}/default/weston
|
|
|
|
# Install Weston systemd service and accompanying udev rule
|
|
install -D -p -m0644 ${WORKDIR}/weston.service ${D}${systemd_system_unitdir}/weston.service
|
|
install -D -p -m0644 ${WORKDIR}/weston.socket ${D}${systemd_system_unitdir}/weston.socket
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -p -m0644 ${WORKDIR}/weston-autologin ${D}${sysconfdir}/pam.d/weston-autologin
|
|
fi
|
|
sed -i -e s:/etc:${sysconfdir}:g \
|
|
-e s:/usr/bin:${bindir}:g \
|
|
-e s:/var:${localstatedir}:g \
|
|
${D}${systemd_system_unitdir}/weston.service
|
|
# Install weston-start script
|
|
install -Dm755 ${WORKDIR}/weston-start ${D}${bindir}/weston-start
|
|
sed -i 's,@DATADIR@,${datadir},g' ${D}${bindir}/weston-start
|
|
sed -i 's,@LOCALSTATEDIR@,${localstatedir},g' ${D}${bindir}/weston-start
|
|
if [ -n "${DEFAULTBACKEND}" ]; then
|
|
sed -i -e "/^\[core\]/a backend=${DEFAULTBACKEND}-backend.so" ${D}${sysconfdir}/xdg/weston/weston.ini
|
|
fi
|
|
|
|
if [ "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'yes', 'no', d)}" = "yes" ]; then
|
|
sed -i -e "/^\[core\]/a xwayland=true" ${D}${sysconfdir}/xdg/weston/weston.ini
|
|
fi
|
|
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'no-idle-timeout', 'yes', 'no', d)}" = "yes" ]; then
|
|
sed -i -e "/^\[core\]/a idle-time=0" ${D}${sysconfdir}/xdg/weston/weston.ini
|
|
fi
|
|
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'use-pixman', 'yes', 'no', d)}" = "yes" ]; then
|
|
sed -i -e "/^\[core\]/a use-pixman=true" ${D}${sysconfdir}/xdg/weston/weston.ini
|
|
fi
|
|
|
|
install -dm 755 -o weston -g weston ${D}/home/weston
|
|
}
|
|
|
|
INHIBIT_UPDATERCD_BBCLASS = "${@oe.utils.conditional('VIRTUAL-RUNTIME_init_manager', 'systemd', '1', '', d)}"
|
|
|
|
inherit update-rc.d systemd useradd
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
|
|
# rdepends on weston which depends on virtual/egl
|
|
#
|
|
require ${THISDIR}/required-distro-features.inc
|
|
|
|
RDEPENDS:${PN} = "weston kbd"
|
|
|
|
INITSCRIPT_NAME = "weston"
|
|
INITSCRIPT_PARAMS = "start 9 5 2 . stop 20 0 1 6 ."
|
|
|
|
FILES:${PN} += "\
|
|
${sysconfdir}/xdg/weston/weston.ini \
|
|
${systemd_system_unitdir}/weston.service \
|
|
${systemd_system_unitdir}/weston.socket \
|
|
${sysconfdir}/default/weston \
|
|
${sysconfdir}/pam.d/ \
|
|
/home/weston \
|
|
"
|
|
|
|
CONFFILES:${PN} += "${sysconfdir}/xdg/weston/weston.ini ${sysconfdir}/default/weston"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "weston.service weston.socket"
|
|
USERADD_PARAM:${PN} = "--home /home/weston --shell /bin/sh --user-group -G video,input weston"
|
|
GROUPADD_PARAM:${PN} = "-r wayland"
|
|
|