forked from brl/citadel
Bruce Leidl
e20e601129
Updated Recipes: gcr4 3.92 -> 4.0.0 geoclue 2.5.7 -> 2.7.0 gjs 1.73.2 -> 1.77.90 gnome-backgrounds 42.0 -> 45.0 gnome-control-center 43.0 -> 45.0 gnome-desktop 43.rc -> 44.0 gsettings-desktop-schema 43.0 -> 45.0 libblockdev 2.26 -> 2.28 libgweather4 4.0.0 -> 4.2.0 libnma 1.8.38 -> 1.10.6 mozjs 102 -> 115 nss 3.64 -> 3.74 ovmf 202205 -> 202211 New recipes: appstream 0.16.3 libei 1.1.0 libxmlb 0.3.14 tecla 45.0 webm/libvpx 1.13 Recipes updated to replace poky recipes with insufficient version: glib-2.0 2.78.0 gtk+/gtk+3 3.24.38 gtk+/gtk4 4.12.1 icu 73_2 wayland/wayland 1.22.0 wayland/wayland-protocols 1.32 wayland/libinput 1.24.0 libadwaita 1.4.0
62 lines
2.2 KiB
BlitzBasic
62 lines
2.2 KiB
BlitzBasic
SUMMARY = "The Geolocation Service"
|
|
DESCRIPTION = "Geoclue is a D-Bus service that provides location information. \
|
|
The primary goal of the Geoclue project is to make creating location-aware applications \
|
|
as simple as possible, while the secondary goal is to ensure that no application \
|
|
can access location information without explicit permission from user."
|
|
LICENSE = "GPL-2.0-or-later"
|
|
SECTION = "console/network"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=bdfdd4986a0853eb84eeba85f9d0c4d6"
|
|
|
|
DEPENDS = "glib-2.0 dbus json-glib libsoup-3.0 intltool-native"
|
|
|
|
inherit meson pkgconfig gtk-doc gobject-introspection vala useradd
|
|
|
|
SRCREV = "bbfb6289dedb88cb8155d9f6868787d5432e1f90"
|
|
SRC_URI = "git://gitlab.freedesktop.org/geoclue/geoclue.git;protocol=https;branch=master \
|
|
file://0001-libgeoclue-don-t-try-to-use-g-ir-scanner-when-intros.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# Without this line, package is declared a library and named libgeoclue*
|
|
AUTO_LIBNAME_PKGS = ""
|
|
|
|
PACKAGECONFIG ??= "3g modem-gps cdma nmea lib"
|
|
PACKAGECONFIG[3g] = "-D3g-source=true,-D3g-source=false,modemmanager"
|
|
PACKAGECONFIG[modem-gps] = "-Dmodem-gps-source=true,-Dmodem-gps-source=false,modemmanager"
|
|
PACKAGECONFIG[cdma] = "-Dcdma-source=true,-Dcdma-source=false,modemmanager"
|
|
PACKAGECONFIG[nmea] = "-Dnmea-source=true,-Dnmea-source=false,avahi,avahi-daemon"
|
|
PACKAGECONFIG[lib] = "-Dlibgeoclue=true,-Dlibgeoclue=false"
|
|
|
|
GTKDOC_MESON_OPTION = "gtk-doc"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Ddbus-sys-dir=${sysconfdir}/dbus-1/system.d \
|
|
-Ddemo-agent=false \
|
|
"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/polkit-1 --shell /bin/nologin polkitd"
|
|
|
|
do_install:append() {
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'modem-gps', 'true', 'false', d)}; then
|
|
# Fix up permissions on polkit rules.d to work with rpm4 constraints
|
|
chmod 700 ${D}/${datadir}/polkit-1/rules.d
|
|
chown polkitd:root ${D}/${datadir}/polkit-1/rules.d
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1/system-services \
|
|
${datadir}/polkit-1/rules.d \
|
|
${libdir} \
|
|
${systemd_unitdir} \
|
|
${prefix}/libexec \
|
|
"
|
|
|
|
FILES:${PN}-dev += " \
|
|
${datadir}/dbus-1/interfaces \
|
|
${datadir}/gir-1.0 \
|
|
"
|