forked from brl/citadel
41 lines
1.6 KiB
PHP
41 lines
1.6 KiB
PHP
|
SUMMARY = "A library on top of GStreamer for building an RTSP server"
|
||
|
|
HOMEPAGE = "http://cgit.freedesktop.org/gstreamer/gst-rtsp-server/"
|
||
|
|
SECTION = "multimedia"
|
||
|
|
LICENSE = "LGPLv2"
|
||
|
|
|
||
|
|
DEPENDS = "gstreamer1.0 libcgroup gstreamer1.0-plugins-base libcheck"
|
||
|
|
|
||
|
|
PNREAL = "gst-rtsp-server"
|
||
|
|
|
||
|
|
SRC_URI = "http://gstreamer.freedesktop.org/src/${PNREAL}/${PNREAL}-${PV}.tar.xz \
|
||
|
|
file://0001-Don-t-hardcode-libtool-name-when-using-introspection.patch \
|
||
|
|
file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch"
|
||
|
|
|
||
|
|
S = "${WORKDIR}/${PNREAL}-${PV}"
|
||
|
|
|
||
|
|
inherit autotools pkgconfig upstream-version-is-even gobject-introspection gtk-doc
|
||
|
|
|
||
|
|
# Starting with 1.8.0 gst-rtsp-server includes dependency-less plugins as well
|
||
|
|
LIBV = "1.0"
|
||
|
|
require gst-plugins-package.inc
|
||
|
|
|
||
|
|
delete_pkg_m4_file() {
|
||
|
|
# This m4 file is out of date and is missing PKG_CONFIG_SYSROOT_PATH tweaks which we need for introspection
|
||
|
|
rm "${S}/common/m4/pkg.m4" || true
|
||
|
|
}
|
||
|
|
|
||
|
|
# gstreamer is not using system-wide makefiles (which we patch in gtkdoc recipe,
|
||
|
|
# but its own custom ones, which we have to patch here
|
||
|
|
patch_gtk_doc_makefiles() {
|
||
|
|
# Patch the gtk-doc makefiles so that the qemu wrapper is used to run transient binaries
|
||
|
|
# instead of libtool wrapper or running them directly
|
||
|
|
sed -i \
|
||
|
|
-e "s|GTKDOC_RUN =.*|GTKDOC_RUN = \$(top_builddir)/gtkdoc-qemuwrapper|" \
|
||
|
|
${S}/common/gtk-doc*mak
|
||
|
|
}
|
||
|
|
|
||
|
|
do_configure[prefuncs] += " delete_pkg_m4_file patch_gtk_doc_makefiles"
|
||
|
|
|
||
|
|
# Needs to be disable due to a dependency on gstreamer-plugins introspection files
|
||
|
|
EXTRA_OECONF_append_mips64 = " --disable-introspection "
|