ef85d1a643
This commit adds meson build support to mutter. It takes a step away from the three separate code bases with three different autotools setups into a single meson build system. There are still places that can be unified better, for example by removing various "config.h" style files from cogl and clutter, centralizing debug C flags and other configurable macros, and similar artifacts that are there only because they were once separate code bases. There are some differences between the autotools setup and the new meson. Here are a few: The meson setup doesn't generate wrapper scripts for various cogl and clutter test cases. What these tests did was more or less generate a tiny script that called an executable with a test name as the argument. To run particular tests, just run the test executable with the name of the test as the argument. The meson setup doesn't install test files anymore. The autotools test suite was designed towards working with installed tests, but it didn't really still, and now with meson, it doesn't install anything at all, but instead makes sure that everything runs with the uninstalled input files, binaries and libraries when running the test suite. Installable tests may come later. Tests from cogl, clutter and mutter are run on 'meson test'. In autotools, only cogl and clutter tests were run on 'make check'.
117 lines
1.9 KiB
Meson
117 lines
1.9 KiB
Meson
cogl_includedir = join_paths(pkgincludedir, 'cogl')
|
|
cogl_srcdir = join_paths(top_srcdir, 'cogl')
|
|
cogl_builddir = join_paths(builddir, 'cogl')
|
|
|
|
cogl_includepath = include_directories('.', 'cogl')
|
|
|
|
cdata = configuration_data()
|
|
cdata.set('HAVE_COGL_GL', have_gl)
|
|
cdata.set('HAVE_COGL_GLES2', have_gles2)
|
|
cdata.set('ENABLE_UNIT_TESTS', have_cogl_tests)
|
|
|
|
cogl_config_h = configure_file(
|
|
input: 'cogl-config.h.meson',
|
|
output: 'cogl-config.h',
|
|
configuration: cdata)
|
|
|
|
# TODO: Remove this when autotools support is removed
|
|
cogl_mutter_config_h = configure_file(
|
|
input: 'cogl-config.h.meson',
|
|
output: 'cogl-mutter-config.h',
|
|
configuration: cdata)
|
|
|
|
cogl_pkg_deps = [
|
|
cairo_dep,
|
|
#uprof_dep,
|
|
glib_dep,
|
|
gobject_dep,
|
|
gmodule_no_export_dep,
|
|
gdk_pixbuf_dep,
|
|
]
|
|
|
|
if have_wayland
|
|
cogl_pkg_deps += [
|
|
wayland_server_dep,
|
|
]
|
|
endif
|
|
|
|
if have_egl
|
|
cogl_pkg_deps += [
|
|
egl_dep,
|
|
]
|
|
endif
|
|
|
|
if have_x11
|
|
cogl_pkg_deps += [
|
|
x11_dep,
|
|
xext_dep,
|
|
xfixes_dep,
|
|
xdamage_dep,
|
|
xcomposite_dep,
|
|
xrandr_dep,
|
|
]
|
|
endif
|
|
|
|
if have_gl
|
|
cogl_pkg_deps += [
|
|
gl_dep,
|
|
]
|
|
endif
|
|
|
|
if have_gles2
|
|
cogl_pkg_deps += [
|
|
gles2_dep,
|
|
]
|
|
endif
|
|
|
|
cogl_deps = [
|
|
cogl_pkg_deps,
|
|
m_dep,
|
|
]
|
|
|
|
cogl_c_args = [
|
|
'-DCOGL_LOCALEDIR="@0@"'.format(localedir),
|
|
'-DCOGL_COMPILATION',
|
|
]
|
|
|
|
if have_gl
|
|
cogl_c_args += [
|
|
'-DCOGL_GL_LIBNAME="@0@"'.format(gl_libname)
|
|
]
|
|
endif
|
|
|
|
if have_gles2
|
|
cogl_c_args += [
|
|
'-DCOGL_GLES2_LIBNAME="@0@"'.format(gles2_libname)
|
|
]
|
|
endif
|
|
|
|
cogl_debug_c_args = []
|
|
if buildtype.startswith('debug')
|
|
cogl_debug_c_args += [
|
|
'-DCOGL_GL_DEBUG',
|
|
'-DCOGL_OBJECT_DEBUG',
|
|
'-DCOGL_ENABLE_DEBUG',
|
|
]
|
|
elif buildtype == 'release'
|
|
cogl_debug_c_args += [
|
|
'-DG_DISABLE_CHECKS',
|
|
'-DG_DISABLE_CAST_CHECKS',
|
|
]
|
|
endif
|
|
|
|
cogl_c_args += cogl_debug_c_args
|
|
|
|
if have_cogl_tests
|
|
subdir('test-fixtures')
|
|
endif
|
|
subdir('cogl')
|
|
subdir('cogl-path')
|
|
subdir('cogl-pango')
|
|
if have_gles2
|
|
subdir('cogl-gles2')
|
|
endif
|
|
if have_cogl_tests
|
|
subdir('tests')
|
|
endif
|