Bruce Leidl
bf78fa6fd2
Then copy it to persistent storage location which can be bind mounted into images
129 lines
4.4 KiB
PHP
129 lines
4.4 KiB
PHP
|
|
SUMMARY = "NetworkManager"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=cbbffd568227ada506640fe950a4823b \
|
|
file://libnm-util/COPYING;md5=1c4fa765d6eb3cd2fbd84344a1b816cd \
|
|
file://docs/api/html/license.html;md5=eb0c003714e5391000fdfd9c9615cccf \
|
|
"
|
|
|
|
DEPENDS = "intltool-native libnl dbus dbus-glib dbus-glib-native libgudev util-linux libnewt polkit libndp python3-pygobject-native python3-pygobject xmlto-native"
|
|
|
|
|
|
export GI_TYPELIB_PATH = "${STAGING_LIBDIR_NATIVE}/girepository-1.0"
|
|
inherit gnomebase gettext systemd bluetooth gobject-introspection upstream-version-is-even python3native gtk-doc
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \
|
|
file://watch-resolvconf.path file://watch-resolvconf.service \
|
|
"
|
|
S = "${WORKDIR}/NetworkManager-${PV}"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-ifcfg-rh \
|
|
--disable-ifnet \
|
|
--disable-ifcfg-suse \
|
|
--disable-json-validation \
|
|
--disable-more-warnings \
|
|
--with-iptables=${sbindir}/iptables \
|
|
--disable-vala \
|
|
--without-selinux \
|
|
--without-wext \
|
|
--with-libnm-glib \
|
|
--with-tests \
|
|
--enable-introspection \
|
|
--with-nmtui=yes \
|
|
"
|
|
|
|
do_compile_prepend() {
|
|
export GIR_EXTRA_LIBS_PATH="${B}/libnm-util/.libs:${B}/libnm/.libs:${B}/libnm-core/.libs:${B}/libnm-glib/.libs"
|
|
}
|
|
|
|
PACKAGECONFIG ??= "nss ifupdown netconfig dhclient concheck \
|
|
${@bb.utils.contains('DISTRO_FEATURES','systemd','systemd','consolekit',d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','bluetooth','${BLUEZ}','',d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES','wifi','wifi','',d)} \
|
|
"
|
|
PACKAGECONFIG[systemd] = " \
|
|
--with-systemdsystemunitdir=${systemd_unitdir}/system --with-session-tracking=systemd --enable-polkit, \
|
|
--without-systemdsystemunitdir, \
|
|
polkit \
|
|
"
|
|
PACKAGECONFIG[bluez5] = "--enable-bluez5-dun,--disable-bluez5-dun,bluez5"
|
|
# consolekit is not picked by shlibs, so add it to RDEPENDS too
|
|
PACKAGECONFIG[consolekit] = "--with-session-tracking=consolekit,,consolekit,consolekit"
|
|
PACKAGECONFIG[modemmanager] = "--with-modem-manager-1=yes,--with-modem-manager-1=no,modemmanager"
|
|
PACKAGECONFIG[ppp] = "--enable-ppp,--disable-ppp,ppp,ppp"
|
|
# Use full featured dhcp client instead of internal one
|
|
PACKAGECONFIG[dhclient] = "--with-dhclient=${base_sbindir}/dhclient,,,dhcp-client"
|
|
PACKAGECONFIG[dnsmasq] = "--with-dnsmasq=${bindir}/dnsmasq"
|
|
PACKAGECONFIG[nss] = "--with-crypto=nss,,nss"
|
|
PACKAGECONFIG[gnutls] = "--with-crypto=gnutls,,gnutls libgcrypt"
|
|
PACKAGECONFIG[wifi] = "--enable-wifi=yes,--enable-wifi=no,wireless-tools,wpa-supplicant wireless-tools"
|
|
PACKAGECONFIG[ifupdown] = "--enable-ifupdown,--disable-ifupdown"
|
|
PACKAGECONFIG[netconfig] = "--with-netconfig=yes,--with-netconfig=no"
|
|
PACKAGECONFIG[qt4-x11-free] = "--enable-qt,--disable-qt,qt4-x11-free"
|
|
PACKAGECONFIG[concheck] = "--enable-concheck,--disable-concheck,curl,curl"
|
|
|
|
PACKAGES =+ "libnmutil libnmglib libnmglib-vpn ${PN}-tests \
|
|
${PN}-nmtui ${PN}-nmtui-doc \
|
|
${PN}-adsl \
|
|
"
|
|
|
|
FILES_libnmutil += "${libdir}/libnm-util.so.*"
|
|
FILES_libnmglib += "${libdir}/libnm-glib.so.*"
|
|
FILES_libnmglib-vpn += "${libdir}/libnm-glib-vpn.so.*"
|
|
|
|
FILES_${PN}-adsl = "${libdir}/NetworkManager/libnm-device-plugin-adsl.so"
|
|
|
|
FILES_${PN} += " \
|
|
${libexecdir} \
|
|
${libdir}/NetworkManager \
|
|
${libdir}/pppd/*/nm-pppd-plugin.so \
|
|
${libdir}/NetworkManager/*.so \
|
|
${datadir}/bash-completion \
|
|
${datadir}/gir-1.0 \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/dbus-1 \
|
|
${base_libdir}/udev/* \
|
|
${systemd_unitdir}/system \
|
|
"
|
|
|
|
RRECOMMENDS_${PN} += "iptables \
|
|
${@bb.utils.contains('PACKAGECONFIG','dnsmasq','dnsmasq','',d)} \
|
|
"
|
|
|
|
FILES_${PN}-dbg += " \
|
|
${libdir}/NetworkManager/.debug/ \
|
|
${libdir}/pppd/*/.debug/ \
|
|
"
|
|
|
|
FILES_${PN}-dev += " \
|
|
${datadir}/NetworkManager/gdb-cmd \
|
|
${libdir}/pppd/*/*.la \
|
|
${libdir}/NetworkManager/*.la \
|
|
"
|
|
|
|
FILES_${PN}-tests = " \
|
|
${bindir}/nm-online \
|
|
"
|
|
|
|
FILES_${PN}-nmtui = " \
|
|
${bindir}/nmtui \
|
|
${bindir}/nmtui-edit \
|
|
${bindir}/nmtui-connect \
|
|
${bindir}/nmtui-hostname \
|
|
"
|
|
|
|
FILES_${PN}-nmtui-doc = " \
|
|
${mandir}/man1/nmtui* \
|
|
"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "NetworkManager.service NetworkManager-dispatcher.service watch-resolvconf.path"
|
|
|
|
do_install_append() {
|
|
rm -rf ${D}/run ${D}${localstatedir}/run
|
|
install -m 644 ${WORKDIR}/watch-resolvconf.path ${D}${systemd_system_unitdir}
|
|
install -m 644 ${WORKDIR}/watch-resolvconf.service ${D}${systemd_system_unitdir}
|
|
}
|