Bruce Leidl
be34ea65f3
- removed layers meta-rust and meta-clang - added new dependencies to Makefile - changed override syntax across all recipe files - updated conf files from hardknott to kirkstone - SRC_URI git URLS fixed to always include branch and protocol - LICENSE fields updated with new naming convention - updated citadel-tools dependencies - upgraded mozjs to mozjs-91 No longer needed because poky includes newer version (or new enough): - glib-2.0 - libgudev - xorgproto - libxfixes - libinput - wayland-protocols - vte
85 lines
2.3 KiB
BlitzBasic
85 lines
2.3 KiB
BlitzBasic
SUMMARY = "GNOME Settings"
|
|
DESCRIPTION = "GNOME Settings is GNOME's main interface for configuration of various aspects of your desktop"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=75859989545e37968a99b631ef42722e"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gettext vala upstream-version-is-even bash-completion features_check
|
|
|
|
DEPENDS = " \
|
|
gdk-pixbuf-native \
|
|
colord-gtk \
|
|
udisks2 \
|
|
upower \
|
|
polkit \
|
|
pulseaudio \
|
|
accountsservice \
|
|
gsettings-desktop-schemas \
|
|
gnome-settings-daemon \
|
|
gnome-desktop \
|
|
modemmanager \
|
|
networkmanager \
|
|
network-manager-applet \
|
|
gnome-bluetooth \
|
|
libgtop \
|
|
libgudev \
|
|
gsound \
|
|
libpwquality \
|
|
ibus \
|
|
libhandy \
|
|
"
|
|
|
|
REQUIRED_DISTRO_FEATURES += " pulseaudio systemd x11"
|
|
|
|
def gnome_verdir(v):
|
|
return oe.utils.trim_version(v, 1)
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/${GNOMEBN}/${@gnome_verdir("${PV}")}/${GNOMEBN}-${PV}.tar.${GNOME_COMPRESS_TYPE};name=archive"
|
|
|
|
SRC_URI[archive.sha256sum] = "ea0c71484c65ce2cc11376f9b01e6211fa4a7ffd334f4307fc52c93f0fddd4c7"
|
|
|
|
|
|
#
|
|
# Extra options have been added to meson_options.txt to make some components of the control
|
|
# center optional. One reason is that these components drag in heavy dependencies, and some
|
|
# of these dependencies have not been packaged and tested yet.
|
|
#
|
|
# Gnome Online Accounts support
|
|
#
|
|
# EXTRA_OEMESON += "-Donline_accounts=true"
|
|
# DEPENDS += "grilo gnome-online-accounts webkitgtk rest"
|
|
#
|
|
# Printer Panel
|
|
#
|
|
# EXTRA_OEMESON += "-Dcups=true"
|
|
# DEPENDS += "cups samba" (only smbclient needed from samba)
|
|
#
|
|
# User Accounts Panel
|
|
#
|
|
# EXTRA_OEMESON += "-Duser_accounts=true"
|
|
# DEPENDS += "accountsservice krb5"
|
|
#
|
|
# Citadel
|
|
#
|
|
# This option disables some things in gnome-control-center such as certain
|
|
# panels that are not used in Citadel, defaults to true in meson_options.
|
|
# To re-enable these things, set the option to false:
|
|
#
|
|
# EXTRA_OEMESON += "-Dcitadel=false"
|
|
#
|
|
|
|
SRC_URI += " file://0001-Add-options-for-Citadel-and-disabling-GOA-CUPS.patch"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/gnome-shell \
|
|
${datadir}/metainfo \
|
|
"
|
|
|
|
FILES:${PN}-dev += "${datadir}/gettext"
|
|
|
|
RDEPENDS:${PN} += "gsettings-desktop-schemas"
|
|
EXTRA_OEMESON = "--buildtype=release -Dcheese=false -Ddocumentation=false -Dstaging_dir=${STAGING_DIR_TARGET}"
|
|
|