Bruce Leidl
8bb03a0582
yocto yocto-3.3 -> yocto-3.3.3 kernel 5.12.4 -> 5.14.9 cryptsetup 2.3.5 -> 2.3.6 libblockdev 2.25 -> 2.26 libbytesize 1.4 -> 2.6 nano 5.6 -> 5.8 udisks2 2.9.2 -> 2.9.3 iwd 1.13 -> 1.17 modemmanager 1.8.2 -> 1.16.8 networkmanager 1.30.2 -> 1.32.10 libgusb 0.2.11 -> 0.3.7 upower 0.99.11 -> 0.99.13 gdm 40.0 -> 41.0 gjs 1.68.0 -> 1.70.0 glib 2.68.0 -> 2.70.0 gnome-backgrounds 40.0 -> 41.0 gnome-control-center 40.0 -> 41.0 gnome-desktop 40.0 -> 41.0 gnome-disk-utility 40.1 -> 41.0 gnome-system-monitor 40.1 -> 41.0 gnome-settings-daemon 40.0.1 -> 41.0 gnome-shell 40.0 -> 41.0 mutter 40.0 -> 41.0 gsettings-desktop-schemas 40.0 -> 41.0 gtk4 4.1.12 -> 4.4.0 gvfs 1.46.1 -> 1.48.1 gnome-terminal 3.40.1 -> 3.41.1 ell 0.39 -> 0.44 mozjs 78.0.1 -> 78.11.0 vte 0.64.0 -> 0.64.2
106 lines
2.6 KiB
BlitzBasic
106 lines
2.6 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
libsm \
|
|
virtual/libx11 \
|
|
libxi \
|
|
glib-2.0 \
|
|
libwacom \
|
|
xcomposite \
|
|
libinput \
|
|
libcanberra \
|
|
mesa \
|
|
upower \
|
|
xserver-xorg \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
graphene \
|
|
graphene-native \
|
|
wayland-protocols \
|
|
wayland-native \
|
|
zenity \
|
|
gobject-introspection \
|
|
gobject-introspection-native \
|
|
"
|
|
|
|
RDEPENDS_${PN} += " xserver-xorg-xwayland zenity"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext upstream-version-is-even features_check
|
|
|
|
def gnome_verdir(v):
|
|
return oe.utils.trim_version(v, 1)
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/${GNOMEBN}/${@gnome_verdir("${PV}")}/${GNOMEBN}-${PV}.tar.${GNOME_COMPRESS_TYPE};name=archive \
|
|
file://0001-Fix-libmutter_dep-in-meson.build-for-Citadel-builds.patch \
|
|
file://0001-Citadel-changes-to-Mutter.patch \
|
|
"
|
|
|
|
SRC_URI[archive.sha256sum] = "fa80a1a744044d88ebfd677ff03203d67705ed2cd624ea06cbb8b58948cdf89e"
|
|
|
|
# x11 is still mandatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "x11 systemd"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dremote_desktop=false \
|
|
-Dtests=false \
|
|
-Dprofiler=false \
|
|
-Dcogl_tests=false \
|
|
-Dlibwacom=true \
|
|
-Dxwayland_initfd=disabled \
|
|
-Dxwayland_path=/usr/bin/Xwayland \
|
|
-Dgles2_libname=libGLESv2.so.2 \
|
|
"
|
|
|
|
MUTTER_API_NAME = "mutter-9"
|
|
|
|
do_install_append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES_${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES_${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
|