Bruce Leidl
e20e601129
Updated Recipes: gcr4 3.92 -> 4.0.0 geoclue 2.5.7 -> 2.7.0 gjs 1.73.2 -> 1.77.90 gnome-backgrounds 42.0 -> 45.0 gnome-control-center 43.0 -> 45.0 gnome-desktop 43.rc -> 44.0 gsettings-desktop-schema 43.0 -> 45.0 libblockdev 2.26 -> 2.28 libgweather4 4.0.0 -> 4.2.0 libnma 1.8.38 -> 1.10.6 mozjs 102 -> 115 nss 3.64 -> 3.74 ovmf 202205 -> 202211 New recipes: appstream 0.16.3 libei 1.1.0 libxmlb 0.3.14 tecla 45.0 webm/libvpx 1.13 Recipes updated to replace poky recipes with insufficient version: glib-2.0 2.78.0 gtk+/gtk+3 3.24.38 gtk+/gtk4 4.12.1 icu 73_2 wayland/wayland 1.22.0 wayland/wayland-protocols 1.32 wayland/libinput 1.24.0 libadwaita 1.4.0
54 lines
1.5 KiB
BlitzBasic
54 lines
1.5 KiB
BlitzBasic
SUMMARY = "VPX multi-format codec"
|
|
DESCRIPTION = "The BSD-licensed libvpx reference implementation provides en- and decoders for VP8 and VP9 bitstreams."
|
|
HOMEPAGE = "http://www.webmproject.org/code/"
|
|
BUGTRACKER = "http://code.google.com/p/webm/issues/list"
|
|
SECTION = "libs/multimedia"
|
|
LICENSE = "BSD-3-Clause"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d5b04755015be901744a78cc30d390d4"
|
|
|
|
SRCREV = "d6eb9696aa72473c1a11d34d928d35a3acc0c9a9"
|
|
SRC_URI += "git://chromium.googlesource.com/webm/libvpx;protocol=https;branch=main \
|
|
file://libvpx-configure-support-blank-prefix.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# ffmpeg links with this and fails
|
|
# sysroots/armv4t-oe-linux-gnueabi/usr/lib/libvpx.a(vpx_encoder.c.o)(.text+0xc4): unresolvable R_ARM_THM_CALL relocation against symbol `memcpy@@GLIBC_2.4'
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
CFLAGS += "-fPIC"
|
|
BUILD_LDFLAGS += "-pthread"
|
|
|
|
export CC
|
|
export LD = "${CC}"
|
|
|
|
VPXTARGET:armv5te = "armv5te-linux-gcc"
|
|
VPXTARGET:armv6 = "armv6-linux-gcc"
|
|
VPXTARGET:armv7a = "${@bb.utils.contains("TUNE_FEATURES","neon","armv7-linux-gcc","generic-gnu",d)}"
|
|
VPXTARGET ?= "generic-gnu"
|
|
|
|
CONFIGUREOPTS = " \
|
|
--target=${VPXTARGET} \
|
|
--enable-vp9 \
|
|
--enable-libs \
|
|
--disable-install-docs \
|
|
--disable-static \
|
|
--enable-shared \
|
|
--prefix=${prefix} \
|
|
--libdir=${libdir} \
|
|
--size-limit=16384x16384 \
|
|
"
|
|
|
|
do_configure() {
|
|
${S}/configure ${CONFIGUREOPTS}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
BBCLASSEXTEND += "native"
|