Bruce Leidl
f4f1f3b153
* citadel-kernel 5.15.8 -> 5.18 * adwaita-icon-theme 42.0 * ell 0.44 -> 0.50 * libnma 1.8.30 -> 1.8.38 * iwd 1.17 -> 1.27 * modemmanager 1.16.8 -> 1.18.6 * networkmanager 1.32.10 -> 1.36.2 * networkmanager-openvpn 1.8.14 -> 1.8.18 * accountsservice 0.6.55 -> 22.08.8 * colord-gtk 0.1.26 -> 0.3.0 * polkit 0.118 -> 0.119 * gexiv2 0.12.1 -> 0.14.0 * gjs 1.70.0 -> 1.72.0 * gnome-autoar 0.4.1 -> 0.4.3 * gnome-backgrounds 0.41.0 -> 0.42.0 * gnome-bluetooth 0.34.3 -> 42.0 * gnome-control-center 41.1 -> 42.1 * gnome-desktop 41.1 -> 42.1 * gnome-disk-utility 41.0 -> 42.0 * gnome-screenshot 40.0 -> 41.0 * gnome-session 40.1.1 -> 42.0 * gnome-settings-daemon 41.0 -> 42.1 * gnome-shell 41.1 -> 42.1 * gnome-system-monitor 41.0 -> 42.0 * gnome-terminal 3.42.1 -> 3.42.2 * gtk4 4.4.1 -> 4.6.4 * gvfs 1.48.1 -> 1.50.0 * libgweather 40.0 -> libgweather4 4.0.0 * mutter 41.1 -> 42.1 * network-manager-applet 1.18.0 -> 1.26.0 * yelp 3.36 -> 42.1 * yelp-xsl 3.36 -> 42.0 * yelp-tools 3.32.2 -> 42.0 * zenity 3.30.0 -> 3.42.1
65 lines
2.6 KiB
BlitzBasic
65 lines
2.6 KiB
BlitzBasic
SUMMARY = "PolicyKit Authorization Framework"
|
|
DESCRIPTION = "The polkit package is an application-level toolkit for defining and handling the policy that allows unprivileged processes to speak to privileged processes."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/polkit"
|
|
LICENSE = "LGPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=155db86cdbafa7532b41f390409283eb \
|
|
file://src/polkit/polkit.h;beginline=1;endline=20;md5=0a8630b0133176d0504c87a0ded39db4"
|
|
|
|
DEPENDS = "expat glib-2.0 intltool-native duktape"
|
|
|
|
inherit autotools gtk-doc pkgconfig useradd systemd gobject-introspection features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "polkit"
|
|
|
|
PACKAGECONFIG = "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', \
|
|
bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[pam] = "--with-authfw=pam,--with-authfw=shadow,libpam,libpam"
|
|
PACKAGECONFIG[systemd] = "--enable-libsystemd-login=yes --with-systemdsystemunitdir=${systemd_unitdir}/system/,--enable-libsystemd-login=no --with-systemdsystemunitdir=,systemd"
|
|
# there is no --enable/--disable option for consolekit and it's not picked by shlibs, so add it to RDEPENDS
|
|
PACKAGECONFIG[consolekit] = ",,,consolekit"
|
|
|
|
PAM_SRC_URI = "file://polkit-1_pam.patch"
|
|
SRC_URI = "http://www.freedesktop.org/software/polkit/releases/polkit-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0003-make-netgroup-support-optional.patch \
|
|
file://0001-pkexec-local-privilege-escalation-CVE-2021-4034.patch \
|
|
file://0002-CVE-2021-4115-GHSL-2021-077-fix.patch \
|
|
file://0003-Added-support-for-duktape-as-JS-engine.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "c8579fdb86e94295404211285fee0722ad04893f0213e571bd75c00972fd1f5c"
|
|
|
|
EXTRA_OECONF = "--with-os-type=moblin \
|
|
--disable-man-pages \
|
|
--disable-libelogind \
|
|
--with-duktape \
|
|
"
|
|
|
|
do_configure:prepend () {
|
|
rm -f ${S}/buildutil/lt*.m4 ${S}/buildutil/libtool.m4
|
|
}
|
|
|
|
do_compile:prepend () {
|
|
export GIR_EXTRA_LIBS_PATH="${B}/src/polkit/.libs"
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-examples"
|
|
|
|
FILES:${PN}:append = " \
|
|
${libdir}/${BPN}-1 \
|
|
${nonarch_libdir}/${BPN}-1 \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/${BPN}-1 \
|
|
${datadir}/gettext \
|
|
"
|
|
|
|
FILES:${PN}-examples = "${bindir}/*example*"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/${BPN}-1 polkitd"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "${BPN}.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|