Bruce Leidl
be34ea65f3
- removed layers meta-rust and meta-clang - added new dependencies to Makefile - changed override syntax across all recipe files - updated conf files from hardknott to kirkstone - SRC_URI git URLS fixed to always include branch and protocol - LICENSE fields updated with new naming convention - updated citadel-tools dependencies - upgraded mozjs to mozjs-91 No longer needed because poky includes newer version (or new enough): - glib-2.0 - libgudev - xorgproto - libxfixes - libinput - wayland-protocols - vte
50 lines
1.7 KiB
Plaintext
50 lines
1.7 KiB
Plaintext
|
|
DEPENDS:append = " citadel-tools-native mtools-native cryptsetup-native coreutils-native"
|
|
|
|
# Block size must be 4096 or dm-verity won't work
|
|
EXTRA_IMAGECMD:ext4 = "-i 4096 -b 4096"
|
|
IMAGE_FSTYPES = "ext4"
|
|
IMAGE_OVERHEAD_FACTOR = "1.2"
|
|
|
|
inherit image
|
|
|
|
CITADEL_IMAGE_CHANNEL ??= "dev"
|
|
CITADEL_IMAGE_COMPRESS ??= "true"
|
|
|
|
do_citadel_mkimage() {
|
|
cat > ${B}/mkimage.conf << EOF
|
|
image-type = "${CITADEL_IMAGE_TYPE}"
|
|
channel = "${CITADEL_IMAGE_CHANNEL}"
|
|
version = ${CITADEL_IMAGE_VERSION}
|
|
timestamp = "${DATETIME}"
|
|
source = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.ext4"
|
|
compress = ${CITADEL_IMAGE_COMPRESS}
|
|
EOF
|
|
|
|
ver=$(printf "%03d" ${CITADEL_IMAGE_VERSION})
|
|
|
|
if [ "${CITADEL_IMAGE_TYPE}" = "kernel" ]; then
|
|
KERNEL_ID=$(generate_kernel_id)
|
|
echo "kernel-version = \"${CITADEL_KERNEL_VERSION}\"" >> ${B}/mkimage.conf
|
|
echo "kernel-id = \"${KERNEL_ID}\"" >> ${B}/mkimage.conf
|
|
fname="citadel-kernel-${CITADEL_KERNEL_VERSION}-${CITADEL_IMAGE_CHANNEL}-${ver}.img"
|
|
else
|
|
fname="citadel-${CITADEL_IMAGE_TYPE}-${CITADEL_IMAGE_CHANNEL}-${ver}.img"
|
|
fi
|
|
citadel-mkimage ${B}
|
|
mv ${B}/${fname} ${IMGDEPLOYDIR}
|
|
}
|
|
|
|
addtask do_citadel_mkimage after do_image_ext4 before do_image_complete
|
|
do_citadel_mkimage[cleandirs] = "${B}"
|
|
do_citadel_mkimage[vardepsexclude] = "DATETIME"
|
|
|
|
IMAGE_POSTPROCESS_COMMAND += " generate_shasum_buildhistory ;"
|
|
|
|
BUILDHISTORY_CURRENT_IMAGE_DIR = "${TOPDIR}/buildhistory/images/${MACHINE_ARCH}/${TCLIBC}/${IMAGE_BASENAME}"
|
|
|
|
generate_shasum_buildhistory() {
|
|
mkdir -p ${BUILDHISTORY_CURRENT_IMAGE_DIR}
|
|
( cd ${IMAGE_ROOTFS} && find . -type f -exec sha1sum '{}' \; | sort -k2 > ${BUILDHISTORY_CURRENT_IMAGE_DIR}/image-shasums.txt )
|
|
}
|