Added a recipe for WireGuard tools.

meta-citadel/recipes-citadel/packagegroups/packagegroup-citadel-base.bb

@@ -64,4 +64,6 @@ RDEPENDS_${PN} = "\
     e2fsprogs \
     dosfstools \
     libpam \
+    wireguard-tools \
+    resolvconf \
 "

meta-citadel/recipes-support/wireguard-tools/wireguard-tools.inc

@@ -0,0 +1,17 @@
+SUMMARY = "WireGuard is an extremely simple yet fast and modern VPN"
+DESCRIPTION="WireGuard is a secure network tunnel, operating at layer 3, \
+implemented as a kernel virtual network interface for Linux, which aims to \
+replace both IPsec for most use cases, as well as popular user space and/or \
+TLS-based solutions like OpenVPN, while being more secure, more performant, \
+and easier to use."
+SECTION = "networking"
+HOMEPAGE = "https://www.wireguard.io/"
+LICENSE = "GPLv2"
+
+LIC_FILES_CHKSUM = "file://../COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRC_URI = "https://git.zx2c4.com/WireGuard/snapshot/WireGuard-${PV}.tar.xz"
+SRC_URI[md5sum] = "890feb4f43886b84d9161ae223957f96"
+SRC_URI[sha256sum] = "c120cdedc3967dcb4ad5c1c7eadd2a1b04ef5dbf2fe60cc8e7c0db337bcda7dc"
+
+S = "${WORKDIR}/WireGuard-${PV}/src/"

meta-citadel/recipes-support/wireguard-tools/wireguard-tools_0.0.20180613.bb

@@ -0,0 +1,27 @@
+require wireguard-tools.inc
+
+inherit bash-completion systemd pkgconfig
+
+DEPENDS = "libmnl"
+
+do_compile_prepend () {
+    cd ${S}/tools
+}
+
+do_install () {
+    cd ${S}/tools
+    oe_runmake DESTDIR="${D}" PREFIX="${prefix}" SYSCONFDIR="${sysconfdir}" \
+        SYSTEMDUNITDIR="${systemd_unitdir}" \
+        WITH_SYSTEMDUNITS=${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'yes', '', d)} \
+        WITH_BASHCOMPLETION=yes \
+        WITH_WGQUICK=yes \
+        install
+}
+
+FILES_${PN} = " \
+    ${sysconfdir} \
+    ${systemd_unitdir} \
+    ${bindir} \
+"
+
+RDEPENDS_${PN} = "bash"